ArrayList and Inheritance explanation

Programming Questions

tezel8

ArrayList and Inheritance explanation

in Programming Questions • 1 year ago

Hello,

I'm trying to get my head around inheritance. All goes well up to the point where I create an ArrayList of objects and need to provide the right argument(s) to get all of its members methods properly initiated.

The 'Bumper' class has the method separate. i don't know where i should be calling this method from and how to provide the ArrayList it is expecting. I'm assuming i should be doing it from the 'Universe' class, since the superclass of 'Bumper' is being called from there.

Hopefully the question and code are clear.

any comments/reference/help will be appreciated.
Thanks in advance

tzl

Universe universe;
int numBoids = 100;
void setup() {
size(600, 400);
smooth();
universe = new Universe();
for (int i = 0; i<numBoids; i++)
universe.add(new Agent(universe));
for (int i = 0; i<(numBoids*2); i++)
universe.add(new Bumper(universe));
}
void draw() {
background(255);
universe.update();
universe.display();
}

class Agent extends Element {
Agent(Universe universe) {
super(universe);
}
void update() {
super.update();
keepInside(universe, 0.5);
}
void keepInside(Universe universe, float efficiency) {
// efficiency ~ 10 : boids immediately rejected
// efficiency ~ .1 : boids slowly change direction
float maxX = universe.x + universe.w;
float maxY = universe.y + universe.h;
// When a boid approach a side, an opposite vector is added to velocity (bounce)
PVector v = new PVector();
if (loc.x <= universe.x + rad ) v.x = (universe.x + rad - loc.x) * efficiency;
else if (loc.x >= maxX - rad) v.x = (maxX - rad- loc.x) * efficiency;
if (loc.y<= universe.y + rad) v.y = (universe.y + rad- loc.y) * efficiency;
else if (loc.y >= maxY - rad) v.y = (maxY- rad - loc.y) * efficiency;
vel.add(v);
}
void display() {
super.display();
noFill();
stroke(5);
ellipseMode(CENTER);
ellipse(loc.x, loc.y, rad, rad);
}
}

class Bumper extends Element {
float maxspeed;
float maxforce;
Bumper(Universe universe) {
super(universe);
maxspeed = 0.75;
maxforce = 0.25;
}
void applyForce(PVector force) {
// We could add mass here if we want A = F / M
acc.add(force);
}
// Separation
// Method checks for nearby vehicles and steers away
void separate (ArrayList<Bumper> bumpers) {
float desiredseparation = rad*2;
PVector sum = new PVector();
int count = 0;
// For every boid in the system, check if it's too close
for (Bumper other : bumpers) {
float d = PVector.dist(loc, other.loc);
// If the distance is greater than 0 and less than an arbitrary amount (0 when you are yourself)
if ((d > 0) && (d < desiredseparation)) {
// Calculate vector pointing away from neighbor
PVector diff = PVector.sub(loc, other.loc);
diff.normalize();
diff.div(d); // Weight by distance
sum.add(diff);
count++; // Keep track of how many
}
}
// Average -- divide by how many
if (count > 0) {
sum.div(count);
// Our desired vector is the average scaled to maximum speed
sum.normalize();
sum.mult(maxspeed);
// Implement Reynolds: Steering = Desired - Velocity
PVector steer = PVector.sub(sum, vel);
steer.limit(maxforce);
applyForce(steer);
}
}
void update() {
super.update();
// Limit speed
vel.limit(maxspeed);
loc.add(vel);
// Reset accelertion to 0 each cycle
acc.mult(0);
}
void display() {
noStroke();
fill(255, 20, 36);
ellipseMode(CENTER);
ellipse(loc.x, loc.y, rad, rad);
}
}

class Element {
Universe universe;
PVector loc, vel, acc;
float rad;
Element(Universe universe)
{
this(universe, universe.randomPos());
}
Element(Universe universe, PVector loc)
{
this.universe = universe;
this.loc = loc;
vel = new PVector(random(-2, 2), random(-2, 2));
acc = new PVector(0, 0);
rad = random(4, 5);
}
void display() {
}
void update() {
loc.add(vel);
}
}

class Universe {
int x, y, w, h;
ArrayList <Element> element;
Universe() {
x = 0;
y = 0;
w = width;
h = height;
element = new ArrayList<Element>();
}
PVector randomPos() {
return new PVector(random(x, x+w), random(y, y+h));
}
Element getIt(int i)
{
return (Element)element.get(i);
}
void add(Element e)
{
element.add(e);
}
void add(Element e, int n)
{
for (int i=0; i < n; i++)
element.add(e);
}
void update() {
for (int i = 0; i<element.size(); i++) {
Element el = (Element) element.get(i);
el.update();
}
}
void display() {
for (int i = 0; i<element.size(); i++)
((Element)getIt(i)).display();
}
}

Replies(4)

calsign

Re: ArrayList and Inheritance explanation

1 year ago

I don't quite understand your application, but I think I understand your problem that deals with your inheritance: You have a class, class A, with two classes that extend it, class B and class C. Since both B and C extend A, you create an ArrayList storing all of the elements. However, class C has a method that you need to call that neither class A or class B has, so you can't call it from the array.

This may not be the best situation for a single ArrayList because class B and class C vary slightly. However, keeping the setup, you could add a separate() method to class A, leave it empty, and then override it in class C. This isn't necessarily preferred, but it should work.

tezel8

Re: ArrayList and Inheritance explanation

1 year ago

Hi,

Thanks for replying. I'm just becoming familiar with the language so my programs are indeed quite messy.
Could you be so kind and explain a more effective and organized way of dealing with this situation? and if time permits, why the solution you suggested is not preferred?

If it is of any relevance, here is what i would like to do:
I'm exploring the idea of autonomous agents/boids.
The class "Element" (class A) provides some characteristics shared by all the elements I'd like to have in the program.
Class A is extended by two other classes, as you have said, class B and C. These two classes differ in that one will only perform a "seek and find" behavior and the other will follow the "separation" rule and no "seek and find"..
I'd like to have different classes that follow different behaviors and have different elements that classes B and C could react to, such as food, attractors, predators... etc..
I thought that by using an ArrayList and a superclass A of which all the elements are a subclass, it would be easier to keep track of what they do and their state etc...
I came across the issue I initially posted and have been thinking of ways I could eventually access elements of a specific class in the ArrayList. but can't figure it out..
Is it better to just create an ArrayList for each of the classes?

Once again, I appreciate any explanation or comments...
Thank you.

benja

Re: ArrayList and Inheritance explanation

1 year ago

Hey,

you can ckeck if an object is an instance of a specific class and then call its class-functions. Like this:

void update() {
    for (int i = 0; i<element.size(); i++) {
      Element el = (Element) element.get(i);
      el.update();
      // check if element is a Bumper
      if(el instanceof Bumper){
            // cast it to Bumper, to access its propertys / functions
            ((Bumper)el).separate(new ArrayList());
      }
    }
}

But if i understood the separate() - function correctly, then it expects an ArrayList with all other bumper-objects. For this, it would be better to store all bumpers in a seperate arraylist.
But you could still keep their references in the "element"-list, for other purposes.

tezel8

Re: ArrayList and Inheritance explanation

1 year ago

Thanks for the tip

Top Reply