Array or For loop??

General Discussion Other

eric.doc24

in General Discussion • Other • 10 months ago

Hi,

I'm working on a game and I want to throw obstacles across the screen. I have a "box" class for the obstacles and each time one goes out of the sketch, a new box should come from the opposite side. I'm using a class so that when the first ten or so pass, I can increase the level to make them go faster, etcetera.

What kind of function will allow me to create a new instance of the box class each time the previous box leaves the sketch?

I'm guessing I would need to create an array of boxes for the first level and have the for loop control the incrementation of the array?

how can I make this work?

Replies(1)

tfguy44

Re: Array or For loop??

10 months ago

If you know that there are only ever going to be 10 (or a larger, but fixed number of) Boxes at a time, you should have an Array of Boxes. When one leaves the screen, just update it so that it appears to "create" a new Box. Like this:

class BoxClass{
int x,y;
color c;
BoxClass(int _offset){
x = _offset;
y = int(random(height-20));
c = color( random(255), random(255), random(255) );
}
void simulate(){
x--;
if( x == -20 ){
x = width;
y = int(random(height-20));
c = color( random(255), random(255), random(255) );
}
}
void render(){
fill(c);
stroke(0);
rect(x,y,20,20);
}
}
BoxClass[] boxes;
void setup(){
size(220,220);
boxes = new BoxClass[10];
for( int i = 0; i < boxes.length; i ++ ){
boxes[i] = new BoxClass(int( i * width / boxes.length ) );
}
}
void draw(){
background(128);
for( int i = 0; i < boxes.length; i ++ ){
boxes[i].simulate();
boxes[i].render();
}
}

If, however, you want to have an unlimited number of them, you should use an ArrayList of Boxes instead. You could still just update one that has left the screen so that it appears a new one has entered... or even add or remove new ones as the level difficulty requires!

Top Reply

Array or For loop??

Replies(1)

Re: Array or For loop??

Statistics

Tags

Actions

Related Posts