Perhaps you're referring to static and dynamic drawings.

Static would be a drawing which is to be used as background image.
Dynamic would be animations to be drawn above former background image.

Within setup(), all permanent drawings are made.
After that, store the reference of the current screen to a PImage variable using get() -> bg = get();
Then, within draw(), use that static image as background using background() -> background (bg);

Now, you can draw the dynamic animation part upon the static one!  

Here's a link to a sample code I've tweaked recently which uses this approach:
Traffic Light

A more complex approach would be to use multiple canvas buffers w/ PGraphics object.

Thanks a lot GoToLoop! That was just the kind of pointer I was looking for! I'll try this, then I think I need to go further the PGraphics route, because in my example both drawings are dynamics!

it's appropriate - that's what the forum is for... (if it's ok for GoToLoop)

Here is the first shot at another sketch, just to practice... open to any suggestions and/or constructive criticism!


// Analog Clock
// by Angelo Caruso

int frameSec = 24;
int maxX = 500, maxY = 500;
int centX = maxX/2, centY = maxX/2;
PImage bg;
int mediumGrey = 180;
int h;
float hdeg, mdeg, sdeg;

void setup() {
  // Init System
  size(maxX, maxY);
  frameRate(frameSec);
  smooth();
  background(mediumGrey);
  // Design the clock background
  clockBackground();
  bg=get();
}

void draw() {
  //Redraw the Clock Static part
  background(bg);
  //What time is it?
  h=hour();
  if (h>12)
    h-=12;
  hdeg=(float(h)/12)*360;
  mdeg=float(minute())*6;
  sdeg=float(second())*6;
  // Draw ShortHand
  drawHand(int(hdeg), 'h');
  // Draw LongHand
  drawHand(int(mdeg), 'm');
  // Draw vlongHand
  drawHand(int(sdeg), 's'); 
  }

void drawHand (int degree, char hand) {
  float teta, len=0.0;
  int x, y;
  teta=radians(degree-90);
 
  if(hand=='h') {
    stroke(250,0,0);
    strokeWeight(80);
    point(centX,centY);
    strokeWeight(20);
    len=130;
    }
  if(hand=='m') {
    stroke(0,250,0);
    strokeWeight(60);
    point(centX,centY);
    strokeWeight(15);
    len=150;
  }
  if(hand=='s') {
    stroke(0,0,250);
    strokeWeight(30);
    point(centX,centY);
    strokeWeight(5);
    len=180;
  }
  x=int(centX+len*cos(teta));
  y=int(centY+len*sin(teta));
  line(centX, centY, x, y);
  }

void clockBackground() {
  fill(225);
  ellipse(centX, centY, 400, 400);
  strokeWeight(60);
  stroke(200);
  point(centX,centY);
  strokeWeight(35);
  stroke(50,50,250);
  point(centX+180,centY);
  point(centX,centY+180);
  point(centX-180,centY);
  point(centX,centY-180);
}

That's a really nice clock!

Thanks for sharing!

Excellent! You set apart the static background drawing from the dynamic clock arms animation!

Well, just to demonstrate some peculiarities of Java,
I've made an alternative draw() function using local float variables and less type conversions.

I see that you used float() to force a fractional division.
An integer division only happens if both operands are whole values.
So you just need to make at least 1 a non-integer for a fractional division to happen.

So in this line -> hdeg=(float(h)/12)*360;
If you make the number 12 a fractional literal, you don't need to convert h into a float one.

To do so, you have many options:

• 12.0
• 12.
• 12f
• 12d
• 12e0
• (float) 12
• (double) 12

I like 12f better myself!  ^_^  ->  hdeg = h/12f * 360;

Also, you don't need to worry about the other arithmetic operators concerning fractional results.
Only the / has this "whole buggy result" issue!

Another one -> Java auto-converts whole numbers into float/ double ones when necessary.
So if you wish, you can declare variable h as a float rather than one of the whole-data types.
Even though function hour() returns an int, you can assign a float h = hour(); w/ no problems at all!

So now it ends my curious Java tips for ya. And here's my take on the draw() function:

void draw() {
  //Redraw the Clock Static part
  background(bg);
  //Declare local variables
  int h;
  final float hdeg, mdeg, sdeg;
  //What time is it?
  if ( (h=hour()) > 12 )    h-=12;
  hdeg=h/12f * 360;
  mdeg=minute()*6;
  sdeg=second()*6;
  // Draw ShortHand
  drawHand(hdeg, 'h');
  // Draw LongHand
  drawHand(mdeg, 'm');
  // Draw vlongHand
  drawHand(sdeg, 's');
}

Thanks a lot GoToLoop!

Your explanation about numeric conversions was a ray of light in the dark, thanks a lot, clear and right to the point.

So what follows is a new release with your suggestions inside or, at least, what I understood from your suggestions !

THis new clock now is alive and ticking, thanks to the Minim library.

Just one more thing: minim seems to be picky wiith aiff (and wav) files. The file as downloaded from www.freesound.org was not understood at all by it, while working with other programs including Quicktime. Just reading it in Audacity and saving without modifications made the magic. Any idea about this? I found another guy in this forum had the same issue.

Here is the new clock and thank you all here for the help! By the way, which is the magic to have the source treated as source, as I saw in other discussions?


-------------------------------------------------------------------


// Analog Clock
// by Angelo Caruso
//
// Sound file
// http://www.freesound.org/people/gherat/sounds/139635/
// Thanks to gherat

import ddf.minim.*;

int frameSec = 24;
int maxX = 500, maxY = 500;
int centX = maxX/2, centY = maxX/2;
PImage bg;
int mediumGrey = 180;
int oldsec;
Minim minim;
AudioSample player;

void setup() {
  // Init System
  size(maxX, maxY);
  frameRate(frameSec);
  smooth();
  background(mediumGrey);
  // Design the clock background
  clockBackground();
  bg=get();
  //Try sound
  minim= new Minim(this);
  player = minim.loadSample("Clock.aiff");
  oldsec=second();
}

void draw() {
  //Redraw the Clock Static part
  // with suggestions by GoToLoop
  int h,sec;
  final float hdeg, mdeg, sdeg;
  background(bg);
  //What time is it?
  if ((h=hour()) > 12)  h-=12;
  hdeg=h/12f*360;
  mdeg=minute()*6;
  sec=second();
  sdeg=sec*6;
  // Draw ShortHand
  drawHand(int(hdeg), 'h');
  // Draw LongHand
  drawHand(int(mdeg), 'm');
  // Draw vlongHand
  drawHand(int(sdeg), 's'); 
  if (sec!=oldsec) {
    player.trigger();
    oldsec=sec;
  }
  }

void drawHand (int degree, char hand) {
  float teta, len=0.0;
  int x, y;
  teta=radians(degree-90);
 
  if(hand=='h') {
    stroke(250,0,0);
    strokeWeight(80);
    point(centX,centY);
    strokeWeight(20);
    len=130;
    }
  if(hand=='m') {
    stroke(0,250,0);
    strokeWeight(60);
    point(centX,centY);
    strokeWeight(15);
    len=150;
  }
  if(hand=='s') {
    stroke(0,0,250);
    strokeWeight(30);
    point(centX,centY);
    strokeWeight(5);
    len=180;
  }
  x=int(centX+len*cos(teta));
  y=int(centY+len*sin(teta));
  line(centX, centY, x, y);
//  player.trigger();
}

void clockBackground() {
  fill(225);
  ellipse(centX, centY, 400, 400);
  strokeWeight(60);
  stroke(200);
  point(centX,centY);
  strokeWeight(35);
  stroke(50,50,250);
  point(centX+180,centY);
  point(centX,centY+180);
  point(centX-180,centY);
  point(centX,centY-180);
}

void stop() {
  player.close();
  super.stop();
}


-------------------------------------------------------------------

I had more modifications along the code. And that's why my draw() version hadn't blended in with yours so well.
Unfortunately, Minim is not working in my particular WinXP setup. 
And what do you mean about the magic to a source be treated as a source? 
Here's my full take on a slightly tweaked code of yours, just for the sake of it: 

/**
 // Analog Clock (v3.0)
 // by Angelo Caruso (2013/Jan)
 //
 // http://forum.processing.org/topic/animation-erasing-and-keeping-method
 //
 // File for Sound
 // http://www.freesound.org/people/gherat/sounds/139635/
 // Thanks to gherat
 */

import ddf.minim.*;

final static byte  fps = 24;
final static short maxX  = 500, maxY = 500;
final static short centX = maxX>>1, centY = maxX>>1;
final static color mediumGrey = 180;

int oldSec = second();
PImage bg;

final Minim minim = new Minim(this);
AudioSample player;

void setup() {
  // Init System
  size(maxX, maxY);
  frameRate(fps);
  smooth();

  // Design the clock background
  clockBackground();
  bg=get();

  //Try sound
  player = minim.loadSample("Clock.aiff");
}

void draw() {
  //Redraw the Clock Static part
  //with suggestions by GoToLoop
  background(bg);

  // Temp. Time Vars.
  int h;
  final int s, hdeg, mdeg, sdeg;

  //What time is it?
  if (( h=hour() ) > 12)   h-=12;
  hdeg = round(h/12f * 360);
  mdeg = minute()*6;
  s = second();
  sdeg = s*6;

  // Draw ShortHand
  drawHand(hdeg, 'h');
  // Draw LongHand
  drawHand(mdeg, 'm');
  // Draw vlongHand
  drawHand(sdeg, 's');

  if (s!=oldSec) {
    player.trigger();
    oldSec=s;
  }
}

void drawHand(final int degree, final char hand) {
  final int x, y, len;
  final float teta = radians(degree-90);

  if (hand=='h') {
    stroke(#FA0000);
    strokeWeight(80);
    point(centX, centY);
    strokeWeight(20);
    len=130;
  }
  else if (hand=='m') {
    stroke(#00FA00);
    strokeWeight(60);
    point(centX, centY);
    strokeWeight(15);
    len=150;
  }
  else if (hand=='s') {
    stroke(#0000FA);
    strokeWeight(30);
    point(centX, centY);
    strokeWeight(5);
    len=180;
  }
  else    len=0;

  x = centX + round(cos(teta)*len);
  y = centY + round(sin(teta)*len);

  line(centX, centY, x, y);
}

void clockBackground() {
  background(mediumGrey);
  fill(225);
  ellipse(centX, centY, width-100, height-100);

  strokeWeight(60);
  stroke(200);
  point(centX, centY);

  strokeWeight(35);
  stroke(50, 50, 250);
  point(centX+180, centY);
  point(centX, centY+180);
  point(centX-180, centY);
  point(centX, centY-180);
}

void stop() {
  player.close();
  super.stop();
}

Paste code, select it, hit the misnamed Insert Code button (third from the left), see your empty lines disappear because Zoho can't code.