Ani onStart callback doesn't respect delay

jonobr1

Ani onStart callback doesn't respect delay

in Contributed Library Questions • 1 year ago

Been messing around with Ani lately and it's a fantastic little library. Inspecting the example Ani_Callback and adding a delay to the instantiation of diameterAni doesn't delay the onStart callback invoked. I expected that it would — is there a way to account for this?

e.g:

/**
* shows how to use the callback features onStart and onEnd
*
* MOUSE
* click : set end of animation and trigger a new one
*/
import de.looksgood.ani.*;
float x = 256;
float y = 256;
int diameter = 50;
Ani diameterAni;
void setup() {
size(512,512);
smooth();
noStroke();
// Ani.init() must be called always first!
Ani.init(this);
// define a Ani with callbacks, specify the method name after the keywords: onStart and onEnd
diameterAni = new Ani(this, 1.5, 2, "diameter", 150, Ani.EXPO_IN_OUT, "onStart:itsStarted, onEnd:newRandomDiameter");
// side info: it's also possible to define this in a static way
//diameterAni = Ani.to(this, 1.5, "diameter", 150, Ani.EXPO_IN_OUT, "onStart:itsStarted, onEnd:newRandomDiameter");
}
void draw() {
background(255);
fill(0);
ellipse(x,y,diameter,diameter);
}
void mouseReleased() {
Ani.to(this, 1.5, "x", mouseX, Ani.ELASTIC_OUT);
Ani.to(this, 1.5, "y", mouseY, Ani.ELASTIC_OUT);
// start diameterAni
diameterAni.start();
}
// there are two possiblities to declare the methods for the callbacks:
// without any parameters or with one parameter of type Ani
// called onStart of diameterAni animation
void itsStarted() {
println("diameterAni started");
}
// called onEnd of diameterAni animation
void newRandomDiameter(Ani theAni) {
float end = theAni.getEnd();
float newEnd = end + random(-20,20);
theAni.setEnd(newEnd);
println("diameterAni finished. current end: "+end+" -> "+"new end: "+newEnd);
}

The onStart method fires when ani.start is called. This is great, but when trying to sync with animations I believe it should fire when the animation starts, not when the start method is called. The only other callback method seems to onEnd.

Not sure what a good workaround would be? Calling ani.isDelaying() until it's false?

—
http://jonobr1.com/

Replies(4)

akiersky

Re: Ani onStart callback doesn't respect delay

7 months ago

Hi jonobr1,

Working with ani on a simple slideshow app and I've been having some troubles with Ani's callbacks, which brought me to your question here.

First off, it looks like the updated version of Ani has a onDelayEnd callback that is called when the delay is complete, I think it solves your problem:

http://www.looksgood.de/libraries/Ani/examples/Ani_Callback_Delay_End/Ani_Callback_Delay_End.pde

I'm having another issue with the callbacks and adjusting the variables they are effecting. Here's my sketch that illustrates the issue:

import de.looksgood.ani.*;
import de.looksgood.ani.easing.*;
PImage img1, img2;
float fader;
Ani fade;
void setup () {
size(500, 500);
Ani.init(this);
img1 = loadImage("img1.jpg").get(0, 0, width, height);
img2 = loadImage("img2.jpg").get(0, 0, width, height);
fader = 255;
fade = new Ani(this, 3.0, "fader", 0, Ani.EXPO_IN_OUT, "onStart:swapImgs, onDelayEnd:delayEnd, onEnd:ended");
//fade = new Ani(this, 3.0, "fader", 0, Ani.EXPO_IN_OUT, "onStart:started, onDelayEnd:swapImgs, onEnd:delayEnd");
//fade = new Ani(this, 3.0, "fader", 0, Ani.EXPO_IN_OUT, "onStart:started, onDelayEnd:delayEnd, onEnd:swapImgs");
fade.pause();
}
void draw () {
background(255);
noTint();
image(img2, 0, 0);
tint(255, fader);
image(img1, 0, 0);
}
void mousePressed () {
fade.start();
}
void started() {
println("started");
}
void delayEnd() {
println("delay End");
}
void ended() {
println("ended");
}
void swapImgs() {
println("swapping images");
fader= 255;
PImage i = img2;
img2 = img1;
img1 = i;
i = null;
}

It seems like either of the three fade objects (lines 19-21) should behave the same, however only the first one works as expected. Am I missing something here?

thanks,

jonobr1

Re: Ani onStart callback doesn't respect delay

7 months ago

Hey AK,

Yes, that method was added by my request through this thread :)

Off hand looking at your code, nothing out of the ordinary pops out. Those three lines should behave the same way, except for when the animation is actually fired.

—
http://jonobr1.com/

akiersky

Re: Ani onStart callback doesn't respect delay

7 months ago

Awesome! glad to see the devs of the library watch for these postings!

As far as I can tell, it seems like Ani captures or caches the values it is changing and dosen't like to release them.

Trying to set the value at the end of the animation is the most telling of this problem. When I trace the value of 'fader' at the beginning and end of the swapImgs() method, it correctly changes. But when the animation starts again, if I trace 'fader' it is set bak to 0.

I'm not sure if it's related, but I have also had troubles with Ani completely getting to values when animating. For example:

import de.looksgood.ani.*;
import de.looksgood.ani.easing.*;
float x1, x2, x3, x4, x5;
float y1, y2, y3, y4, y5;
float target;
void setup() {
size(500, 500);
Ani.init(this);
target = 0;
y1 = 0;
y2 = 100;
y3 = 200;
y4 = 300;
y5 = 400;
x1 = 400;
x2 = 400;
x3 = 400;
x4 = 400;
x5 = 400;
}
void draw() {
background(255);
fill(0);
rect(x1, y1, 100, 100);
rect(x2, y2, 100, 100);
rect(x3, y3, 100, 100);
rect(x4, y4, 100, 100);
rect(x5, y5, 100, 100);
}
void mousePressed() {
Ani.to(this, 1, 0.1, "x1", target, Ani.EXPO_IN_OUT);
Ani.to(this, 1, 0.2, "x2", target, Ani.EXPO_IN_OUT);
Ani.to(this, 1, 0.3, "x3", target, Ani.EXPO_IN_OUT);
Ani.to(this, 1, 0.4, "x4", target, Ani.EXPO_IN_OUT);
Ani.to(this, 1, 0.5, "x5", target, Ani.EXPO_IN_OUT);
if(target == 0) {
target = 400;
} else {
target = 0;
}
}

after animating left than right, one of the squares isn't quite aligned:

I've had this happen quite often and have gotten in the habit of adding the onEnd callback to set a value to it's correct position when it's critical. I found the same problem (only worse) with the motionlib library, which is what brought me to Ani as my new fave.

I guess at least one of the three methods works correctly. Thanks for the reply!

morpholux

Re: Ani onStart callback doesn't respect delay

6 months ago

Not sure if I understand the details of this post, but I noticed that the problem is solved if you just shift a bit the value of the third parameters.

Ani.to(this, 1, 0.29999999, "x3", target, Ani.EXPO_IN_OUT);

It is almost 0,3 of a second, and the value obtain for x3 are exactly what you excepted with other cases : from 0.0 to 400.0.

So it has something to do with the precision of the division I supposed.

Top Reply