Alpha transparency not honored in PGraphics

General Discussion Other

hspencer

Alpha transparency not honored in PGraphics

in General Discussion • Other • 9 months ago

I've been using PGraphics to create a secuence of transparent images (exported to .PNG files). Since I've updated to version 2.0b7 all images appear with gray background. I've checked previous code that worked fine before and now it doesn't. Any clue on this?

Replies(5)

PhiLho

Re: Alpha transparency not honored in PGraphics

9 months ago

I just tested the following sketch, and it still works in 2.0b7, so I think you should be a bit more explicit, or show a similar little sketch failing to work.

void setup()
{
size(800, 800);
PGraphics pg = createGraphics(500, 500);
pg.beginDraw();
pg.fill(#00AAFF);
pg.ellipse(250, 250, 250, 250);
pg.endDraw();
pg.save("H:/Temp/Foo.png");
exit();
}

hspencer

Re: Re: Alpha transparency not honored in PGraphics

9 months ago

Thanks!
this is the code that used to work and now doesn't:

int total = 100;
PGraphics[] img = new PGraphics[total];
int count = 0;
void setup() {
size(20, 20, P2D);
createAllGraphics();
}
void createAllGraphics() {
for (int i = 0; i < total; i++) {
img[i] = createGraphics(width, height, P2D);
}
}
void draw() {
img[count].beginDraw();
img[count].noStroke();
/* círculo negro */
img[count].fill(255, 120);
img[count].ellipse(width/2, height/2, 17, 17);
img[count].ellipse(width/2 + 1, height/2 + 1, 16, 16);
img[count].ellipse(width/2 + 2, height/2 + 2, 16, 16);
img[count].fill(0);
img[count].ellipse(width/2, height/2, 16, 16);
/* porcentaje */
img[count].pushMatrix();
img[count].translate(width/2, height/2);
img[count].rotate(- PI);
float t = map(count, 0, total, 0, TWO_PI);
float increment = 0.1;
img[count].fill(255);
img[count].beginShape();
img[count].vertex(0, 0);
float radio = 16/2;
for (float ang = 0; ang <= t; ang += increment) {
img[count].vertex(sin(ang) * radio, cos(ang) * radio);
}
String n = nf(count, 2);
img[count].endShape();
img[count].popMatrix();
img[count].endDraw();
img[count].save("img/percentage-left-"+n+".png");
count++;
if (count >= total) {
println("done!");
exit();
}
}

but using Amnon's advice:

img[count].background(0,0);

Everything worked fine! thanks

amnon.owed

Re: Alpha transparency not honored in PGraphics

9 months ago

You didn't mention the renderer. This is important because there are differences between the default JAVA2D renderer and the P2D/P3D OpenGL renderers. I am assuming you are experiencing problems with the P2D/P3D renderers, because I have had the same problem.

I have filed an issue about this, but it got fried. So you just have to explicitly clear the background with pg.background(0, 0);

Some of my other filed issues (see here) with regard to transparency in PGraphics have been fixed by andres. Those are available when you build from svn.

Note that I've also seen differences in transparency behavior between different video cards in Processing 2.0b7. In the latest svn build those discrepancies seem to have been solved.

hspencer

Re: Alpha transparency not honored in PGraphics

9 months ago

Yes, you are right, I was using P2D.
Thanks Amnon!

PhiLho

Re: Alpha transparency not honored in PGraphics

9 months ago

Or just stick to JAVA2D as I did... I was suspecting an OpenGL transparency issue (these are common) but it is better to have something concrete rather than speculating...

Top Reply