adding stop , forward , backward

Programming Questions

mataarsak

adding stop , forward , backward

in Programming Questions • 1 year ago

this code read data from a text file and draw a car object that moves according to the positions in the text file . now I create stop , forward and backward button . How could I perform stop , forward backward it ?

import apwidgets.*;
boolean ret = false;
boolean st = true;
float zoom;
// A vector to store the offset from the center
PVector offset;
// The previous offset
PVector poffset;
// A vector for the mouse position
PVector mouse;
Car myCar1;
PImage car;
String[] lines;
int index = 0;
void setup() {
size(screenWidth, screenHeight, OPENGL);
zoom = 1.0;
offset = new PVector(0, 0);
poffset = new PVector(0, 0);
myCar1 = new Car(color(108, 87, 229));
car = loadImage("3.jpg");
smooth();
}
void draw() {
background(255);
pushMatrix();
// draw stop button
fill(106,90,205);
stroke(106,90,205);
smooth();
ellipse(650,700,50,50);
fill(255);
stroke(255);
rect(650,700,15,15);
// draw forward button
fill(106,90,205);
stroke(106,90,205);
rect(500,700,90,45);
fill(255);
stroke(255);
smooth();
triangle(500,700,525,710,525,690);
triangle(475,700,500,710,500,690);
fill(106,90,205);
stroke(106,90,205);
rect(800,700,90,45);
fill(255);
stroke(255);
triangle(800,690,800,710,825,700);
triangle(775,690,775,710,800,700);
// draw backward button
// Everything must be drawn relative to center
translate(width/2, height/2);
frameRate(10);
// Use scale for 2D "zoom"
scale(zoom);
// The offset (note how we scale according to the zoom)
translate(offset.x/zoom, offset.y/zoom);
image(car, -3, -120, car.width/4, car.height/4);
lines = loadStrings("positions.txt");
myCar1.Move();
rect(150, 150, 10, 20);
// An arbitrary design so that we have something to see!
randomSeed(1);
stroke(0);
noFill();
rectMode(CENTER);
float h = 100;
popMatrix();
}
class Car {
color c;
int z = 10;
int t = 20;
Car(color tempC) {
c = tempC;
}
void display() {
fill(162, 211, 172);
rect(200, 200, 10, 30);
}
void Move() {
fill(c);
if (index < lines.length) {
if( st = true){
String[] pieces = split(lines[index], '\t');
if (pieces.length == 2) {
int x = int(pieces[0]);
int y = int(pieces[1]);
rect (x-z/16, y-t/2, z, t);
ellipse(x, y, 5, 5);
}
// Go to the next line for the next run through draw()
index = index + 1;
}
}
}
}
void mousePressed()
{
mouse = new PVector(mouseX, mouseY);
poffset.set(offset);
if ( mouseY > 680 )
{
//Backward
if ( mouseX < 590 & 480 < mouseX ){
BACKWATD
}
//forward
else if ( mouseX < 890 & 780 < mouseX){
FORWARD
}
}
// stop
else if (mouseX < 750 & mouseX > 620 ){
STOP
}
}
}

and this is some positions in my text file :

44.8 0.4
45 0
45 0
45.9 -1
46.9 -0.2
47.9 0.5
48 0
49 -1

Replies(1)

benja

Re: adding stop , forward , backward

1 year ago

Loading the position from file on every frame makes no sense. They don't change, so load them in setup().
You should try to seperate the variables which you Car-class uses from the global ones. Object-oriented programming means, that the Car class should not rely on any variables from outside. So "index", "st" and "lines" should be members of the Car class.

A general advice:
It is confusing how you mix drawing and calculating things inside and outside of your class.
Try to seperate the drawing from the calculations and do everything inside of your class. Try to use variables instead of absolute values, it makes things more flexible.

Here is a simplified version of your code, including the forward/backward/stop thing:

import processing.opengl.*;

Car myCar1;
String[] lines;

void setup() {
size(500, 500, OPENGL);
String[] lines = loadStrings("positions.txt");
myCar1 = new Car(color(108, 87, 229), lines);
smooth();
}

void draw() {
background(255);
translate(width/2, height/2);
myCar1.move();
myCar1.display();
}

class Car {
color c;
int x, y, index;
int w = 10;
int h = 20;
int direction = 1;
int[][] positions;

Car(color tempC, String[] pos) {
    c = tempC;
    // parse positions
    positions = new int[pos.length][2];
    for (int i = 0; i< pos.length; i++) {
      String[] pieces = split(pos[i], '\t');
      positions[i][0] = int(pieces[0]);
      positions[i][1] = int(pieces[1]);
    }
}

void display() {
    // draw an image of the car
    // here it's just a rectangle
    fill(c);
    rect (x-w/2, y-h/2, w, h);
}
void move() {
    // pick next position
    if ((index+direction)>=0 &&(index+direction)<positions.length) {
      index = index + direction;
    }

    x = positions[index][0];
    y = positions[index][1];

    println(index+ ": "+x+" ; "+y);
}
}

void keyPressed() {
switch(key) {
    case ('f'):
    println("forward");
    myCar1.direction = 1;
    break;
    case ('b'):
    println("backward");
    myCar1.direction = -1;
    break;
    case ('s'):
    println("stop");
    myCar1.direction = 0;
    break;
}
}