Adding in acceleration and momentum

Programming Questions

ekapalka

Adding in acceleration and momentum

in Programming Questions • 2 months ago

Hello! I've been working on this program in which a rectangle is directed about the screen using the WASD keys (or arrow keys... I'm not done yet) , and I'm working on having the "front" of the rectangle always be the front, so that moving "forward" causes it to travel forward, even if the rectangle is rotated. Is this possible, and if so, could someone direct me to where I could learn? Thanks!

boolean left, right, backward, forward;
boolean SOOPASPEED;
int fullspeed = 6;
int regspeed = 1;
PVector pos = new PVector(500, 300);
void setup() {
size(displayWidth, displayHeight, P2D);
frameRate(300);
noCursor();
}
void draw() {
if (left) {
if (SOOPASPEED) { pos.x -= fullspeed; }
else { pos.x -= regspeed; }
}
if (right) {
if (SOOPASPEED) { pos.x += fullspeed; }
else { pos.x += regspeed; }
}
if (backward) {
if (SOOPASPEED) { pos.y += fullspeed; }
else { pos.y += regspeed; }
}
if (forward) {
if (SOOPASPEED) { pos.y -= fullspeed; }
else { pos.y -= regspeed; }
}
if (pos.x>width){pos.x=0; }
if (pos.x<0){pos.x=width; }
if (pos.y>height){pos.y=0;}
if (pos.y<0){pos.y=height;}
stroke(255);
fill(255);
background(0);
rectMode(CENTER);
rect(pos.x, pos.y, 50, 90);
}
void keyPressed() {
if (key == 'a' || key == 'A') { left = true; }
if (key == 'd' || key == 'D') { right = true; }
if (key == 's' || key == 'S') { backward = true; }
if (key == 'w' || key == 'W') { forward = true; }
if(key == CODED) {
if(keyCode == SHIFT) { SOOPASPEED = true; }
}
}
void keyReleased() {
if (key == 'a' || key == 'A') { left = false; }
if (key == 'd' || key == 'D') { right = false; }
if (key == 's' || key == 'S') { backward = false; }
if (key == 'w' || key == 'W') { forward = false; }
if(key == CODED) {
if(keyCode == SHIFT) { SOOPASPEED = false; }
}
}
boolean sketchFullScreen(){
return true;
}

[edit: formatting]

Replies(8)

tfguy44

Re: Adding in acceleration and momentum

2 months ago

I love it when I get to post this.

PVector p=new PVector(110,110,0);float v=0;boolean[] keys=new boolean[4];
void setup(){size(220, 220);smooth();}void draw(){background(0);s();r();}
void keyPressed(){b(true);}void keyReleased(){b(false);}
void b(boolean d){if(key==CODED){if(keyCode==LEFT)keys[0]=d;if(keyCode==RIGHT)keys[1]=d;if(keyCode==UP)keys[2]=d;if(keyCode==DOWN)keys[3]=d;}}
void s(){p.z+=(keys[1]?.1:0)-(keys[0]?.1:0);v+=(keys[2]?.1:0)-(keys[3]?.1:0);p.x=(p.x+width+v*cos(p.z))%width;p.y=(p.y+height+v*sin(p.z))%height;v*=.99;}
void r(){translate(p.x,p.y);rotate(p.z);noStroke();fill(0,128,0); rect(-10,-10,20,20);stroke(0);noFill();triangle(-8,-8,7,0,-8,8);}

tfguy44

Re: Adding in acceleration and momentum

2 months ago

Whee!

final int total_cars = 100;
ArrayList<Car> cars = new ArrayList();
void setup() {
size(600,400);
smooth();
for( int i=0; i < total_cars; i++ ) cars.add( new Car() );
}
void draw() {
background(0);
for( int i=0; i < cars.size(); i++ ) cars.get(i).go();
}
class Car {
float x, y, z, v;
color k;
boolean a, b, c;
Car() {
x=width/2;
y=height/2;
z=random(TWO_PI);
v=random(10);
k=color(random(255), random(255), random(255));
a=b=c=false;
}
void go() {
if ( random(1) > .95 ) a= !a;
if ( random(1) > .95 ) b= !b;
if ( random(1) > .95 ) c= !c;
z+=(a?-.1:0)+(b?.1:0);
v+=(c?.1:0);
x=(x+width+v*cos(z))%width;
y=(y+height+v*sin(z))%height;
v*=.99;
pushMatrix();
translate(x, y);
rotate(z);
noStroke();
fill(k);
rect(-10, -10, 20, 20);
stroke(0);
noFill();
triangle(-8, -8, 7, 0, -8, 8);
popMatrix();
}
}

ekapalka

Re: Adding in acceleration and momentum

2 months ago

That is amazing! The only difference between these things is that mine can strafe left or right and turns with the mouse :P I'll post some code when I get it figured out. Thanks!! [edit] I just realized I left out a major part of my code! Turning! Here's the rest of that:

import java.awt.AWTException;
import java.awt.Robot;
Robot robot;
float b, x;
float tspeed;
PVector middle;
boolean left, right, backward, forward;
boolean SOOPASPEED;
int fullspeed = 12;
int regspeed = 6;
PVector pos = new PVector(width/4, height/4);
//float traction = ; //0 to 1. Affects momentum
//float inertia = ; //0 to 1. Affects acceleration
//float dspeed = ; //Any number. Affects box x&y += ? speed
float turnsns = 5; //turning sensitivity, lower#=higher sensitivity
void setup() {
size(displayWidth, displayHeight, P2D);
textAlign(LEFT, TOP);
textSize(30);
strokeWeight(3);
noCursor();
smooth();
fill(255);
middle = new PVector(width/2, height/2);
try {
robot = new Robot();
}
catch (AWTException e) {
e.printStackTrace();
}
}
void draw() {
PVector dir = PVector.sub(mx(), middle);
float magnitude = dir.mag();
background(255);
fill(0);
String info = "Degrees: " + int(degrees(dir.heading())) + "\nMagnitude: " + int(magnitude);
text(info, 5, 5);
translate(middle.x, middle.y);
line(0, 0, dir.x, dir.y);
robot.mouseMove(int(middle.x), int(middle.y));
tspeed = (int(degrees(dir.heading()))==180)?-(magnitude)/100:((int(degrees(dir.heading()))==0)&&(mouseX!=displayWidth/2))?(magnitude)/100:0;
text("rSpeed:"+tspeed, 100, 100);
text(height, 200, 200);
rectMode(CENTER);
pushMatrix();
translate(pos.x, pos.y);
rotate(b);
rect(0, 0, 50, 90);
b+=tspeed/turnsns;
popMatrix();
//x = (x >=width/2)? -width/2: x+1;
if (left) {
if (SOOPASPEED) { pos.x -= fullspeed; }
else { pos.x -= regspeed; }
}
if (right) {
if (SOOPASPEED) { pos.x += fullspeed; }
else { pos.x += regspeed; }
}
if (backward) {
if (SOOPASPEED) { pos.y += fullspeed; }
else { pos.y += regspeed; }
}
if (forward) {
if (SOOPASPEED) { pos.y -= fullspeed; }
else { pos.y -= regspeed; }
}
if (pos.x>width/2){pos.x=-width/2; }
if (pos.x<-width/2){pos.x=width/2; }
if (pos.y>height/2){pos.y=-height/2;}
if (pos.y<-height/2){pos.y=height/2;}
}
PVector mx() {
return new PVector(mouseX>width/2+100?width/2+100:mouseX<width/2-100?width/2-100:mouseX, displayHeight/2);
}
boolean sketchFullScreen() {
return true;
}
void keyPressed() {
if (key == 'a' || key == 'A') { left = true; }
if (key == 'd' || key == 'D') { right = true; }
if (key == 's' || key == 'S') { backward = true; }
if (key == 'w' || key == 'W') { forward = true; }
if(key == CODED) {
if(keyCode == SHIFT) { SOOPASPEED = true; }
}
}
void keyReleased() {
if (key == 'a' || key == 'A') { left = false; }
if (key == 'd' || key == 'D') { right = false; }
if (key == 's' || key == 'S') { backward = false; }
if (key == 'w' || key == 'W') { forward = false; }
if(key == CODED) {
if(keyCode == SHIFT) { SOOPASPEED = false; }
}
}

Sorry! I'll get right on figuring out your code now :P

GoToLoop

Re: Adding in acceleration and momentum

2 months ago

Nice coding skills you 2!

TFGuy44's sample goes to my collection of online tech programming skills!

http://studio.processingtogether.com/sp/pad/export/ro.9Nl$898UQxW3Q/latest

/** 
 * Drivable Car (v2.11)
 * by  TFGuy44 (2013/Aug)
 * mod GoToLoop
 * 
 * http://forum.processing.org/topic/adding-in-acceleration-and-momentum
 * http://studio.processingtogether.com/sp/pad/export/ro.9Nl$898UQxW3Q/latest
 */

static int gw, gh;
static float x, y, z, v;
static boolean north, south, west, east;

final static float SPD = .2, ROT = .1, ACCEL = .99;

void setup() {
  size(640, 480);
  smooth();

  gw = width;
  gh = height;

  x = gw>>1;
  y = gh>>1;
}

void draw() {
  background(0300);
  update();
  display();
}

void keyPressed() {
  setKeys(keyCode, true);
}

void keyReleased() {
  setKeys(keyCode, false);
}

static final void setKeys(int k, boolean decision) {
  if      (k == UP    | k == 'W')   north = decision;
  else if (k == DOWN  | k == 'S')   south = decision;
  else if (k == LEFT  | k == 'A')   west  = decision;
  else if (k == RIGHT | k == 'D')   east  = decision;
}

static final void update() {
  v += (north? SPD : 0) - (south? SPD : 0);
  z += (east?  ROT : 0) - (west?  ROT : 0);

  x = (x + gw + cos(z)*v) % gw;
  y = (y + gh + sin(z)*v) % gh;

  v *= ACCEL;
}

void display() {
  translate(x, y);
  rotate(z);

  noStroke();
  fill(#008000); 
  rect(-10, -10, 20, 20);

  stroke(0);
  noFill();
  triangle(-8, -8, 7, 0, -8, 8);
}

GoToLoop

Re: Adding in acceleration and momentum

2 months ago

Now multi-cars version mixed w/ single one:

http://studio.processingtogether.com/sp/pad/export/ro.9NBw8x3YGExwu/latest

/** 
 * Rotating Cars (v2.03)
 * by  TFGuy44 (2013/Aug)
 * mod GoToLoop
 * 
 * http://forum.processing.org/topic/adding-in-acceleration-and-momentum
 * http://studio.processingtogether.com/sp/pad/export/ro.9NBw8x3YGExwu/latest
 */

static int gw, gh;
static float x, y, z, v;
static boolean north, south, west, east;

final static float SPD = .2, ROT = .1, ACCEL = .98;

final static short CARS = 50;
final Car[] cars = new Car[CARS];

void setup() {
  size(640, 480);
  smooth();

  gw = width;
  gh = height;

  x = gw>>1;
  y = gh>>1;

  for ( int i = 0; i != CARS; cars[i++] = new Car() );
}

void draw() {
  background(0300);

  for (Car c: cars)  c.go();

  update();
  display();
}

void keyPressed() {
  setKeys(keyCode, true);
}

void keyReleased() {
  setKeys(keyCode, false);
}

static final void setKeys(int k, boolean decision) {
  if      (k == UP    | k == 'W')   north = decision;
  else if (k == DOWN  | k == 'S')   south = decision;
  else if (k == LEFT  | k == 'A')   west  = decision;
  else if (k == RIGHT | k == 'D')   east  = decision;
}

static final void update() {
  v += (north? SPD : 0) - (south? SPD : 0);
  z += (east?  ROT : 0) - (west?  ROT : 0);

  x = (x + gw + cos(z)*v) % gw;
  y = (y + gh + sin(z)*v) % gh;

  v *= ACCEL;
}

void display() {
  translate(x, y);
  rotate(z);

  noStroke();
  fill(-1); 
  rect(-20, -20, 40, 40);

  stroke(0);
  noFill();
  triangle(-15, -15, 15, 0, -15, 15);

  resetMatrix();
}

final class Car {
  boolean a, b, c;
  float x, y;
  float z = random(TWO_PI), v = random(5);
  final color k = (color) random(#000000);

  Car() {
    x = width>>1;
    y = height>>1;
  }

  void go() {
    update();
    display();
  }

  void update() {
    if (random(1) > .98)   a = !a;
    if (random(1) > .95)   b = !b;
    if (random(1) > .95)   c = !c;

    if (a)   v += SPD;
    z += (b? ROT : 0) - (c? ROT : 0);

    x = (x + width  + cos(z)*v) % width;
    y = (y + height + sin(z)*v) % height;

    v *= ACCEL;
  }

  void display() {
    translate(x, y);
    rotate(z);

    noStroke();
    fill(k); 
    rect(-10, -10, 20, 20);

    stroke(0);
    noFill();
    triangle(-8, -8, 7, 0, -8, 8);

    resetMatrix();
  }
}

tfguy44

Re: Adding in acceleration and momentum

2 months ago

We've completely lost the original topic now, but I feel like GoToLoop would be interested in where I took these cars...

ArrayList<Car> cars = new ArrayList();
float goalX, goalY;
int timeStep = 200;
Car gbCar = new Car( -1, "0" );
float gbScore;
String[] str_a;
String[] str_b;
float[] scores;
final int gen_size = 5;
int cur_sub;
int countGen = 0;
void setup() {
size(600, 400);
background(0);
gbScore = dist(0, 0, width, height);
goalX = random(width);
goalY = random(height);
smooth();
ellipseMode(CENTER);
str_a = new String[gen_size];
str_b = new String[gen_size];
scores = new float[gen_size];
for ( int j = 0; j < gen_size; j++ ) {
str_a[j] = starterString();
scores[j] = 0;
}
cur_sub = -1;
countDoneCars = 0;
for ( int i=0; i < gen_size; i++ ) cars.add( new Car( i, str_a[i] ) );
}
String starterString() {
String mut = "" + char( '0' + int( random(4) ) ); // + "00000000" ;
return( mut );
// Ok, a bit more random would be nice.
// I suppose that's ok.
}
int countDoneCars;
String hr( String cr ) {
String r = "";
for ( int t = 0; t < cr.length(); t++) {
if ( cr.charAt(t) == '0' ) r+= 'N';
if ( cr.charAt(t) == '1' ) r+= 'L';
if ( cr.charAt(t) == '2' ) r+= 'R';
if ( cr.charAt(t) == '3' ) r+= 'A';
}
return( r );
}
void draw() {
background(0);
fill(255,0,0);
String extra = "";
//if( gbScore < 10 ) extra = " That's close enough! Click the mouse to move the goal. :-)";
text("Best ever: (" + hr(gbCar.genome) + ") = " + int(gbScore) + extra, 10, 20 );
fill(255,255,0);
text("Generation " + countGen , 10, 34 );
for( int tt=0; tt< gen_size; tt++){
fill(cars.get(tt).k);
text( "(" + hr( cars.get(tt).genome ) + ")", 10, 48 + 14 * tt);
}
// If no car, last car is done, simulate next one.
// If all cars done, simulate next generation.
if ( countDoneCars == gen_size ) { // cars.size() == 0 ) {
while ( cars.size () > 0 ) cars.remove(0);
//cur_sub++;
// If all cars in this generation simulated, create next generation.
//if ( cur_sub == gen_size ) {
countDoneCars = 0; // cur_sub = 0;
//println( "Making next generation..." );
// Always keep the best one, and toss the worse.
arrayCopy( str_a, str_b );
int bestIndex = 0;
int worstIndex = 0;
for ( int j = 0; j < gen_size; j++ ) {
if ( scores[bestIndex] > scores[j] ) {
bestIndex = j;
}
if ( scores[worstIndex] < scores[j] ) {
worstIndex = j;
}
}
str_b[worstIndex] = str_b[bestIndex]; // Replace the worst with a copy of the best for breeding.
// Scramble.
for ( int j = 0; j < gen_size; j++ ) {
str_a[j] = scramble( j, str_b[int(random(gen_size))], str_b[int(random(gen_size))] );
}
//str_a[0] = str_b[bestIndex]; // Always keep the best.
// Add all the cars to simulate.
for ( int j = 0; j < gen_size; j++ ) {
cars.add( new Car( j, str_a[j] ) );
}
countGen++;
//}
//cars.add( new Car( cur_sub, str_a[cur_sub] ) );
}
// Draw the global best car ever.
gbCar.render(); // It don't move, yo.
// Simulate the current subject.
for ( int i=0; i < cars.size(); i++ ) cars.get(i).go(); // It go.
// Draw the cheese.
stroke(255);
fill(random(255));
ellipse(goalX, goalY, 10, 10);
}
String scramble( int which, String a, String b ) {
String r;
int pos = int(random(min(a.length(), b.length())));
r = a.substring(0, pos) + b.substring(pos, b.length());
// Mutation!
if ( random(1) < .5 ) {
pos = int(random(r.length()));
if ( random(1) < .5 ) {
String mut = "" + char( '0' + int( random(4) ) );
//println( "New Car #" + which + ": Mutation! Adding a char: '" + mut + "' at position " + pos );
r = r.substring(0, pos) + mut + r.substring(pos, r.length());
}
else {
if ( r.length() > 0 ) {
pos = int(random(r.length()-1));
//println( "New Car #" + which + ": Mutation! Losing the char at position " + pos );
r = r.substring(0, pos) + r.substring(pos+1, r.length());
}
}
}
return( r );
}
void mousePressed() {
goalX = random(width);
goalY = random(height);
gbScore = dist(0, 0, width, height);
countGen=0;
//println( "GLOBAL BEST: (" + gbCar.genome + ") = " + gbScore );
}
class Car {
float x, y, z, v;
color k;
boolean a, b, c;
int ins; // Current instruction.
int time; // Time of next instruction.
int[] instructions;// = { 3, 1, 1, 3, 1, 2, 2, 2 };
boolean disable;
int myNumber;
String genome;
Car( int oo, String input ) {
x=20; //width/2;
y=height/2;
if ( oo == -1 ) {
x = -20;
y = -20;
}
z=0;//random(TWO_PI);
v=0;//random(10);
k=color(0, random(128, 255), random(128, 255));
a=b=c=false;
// Added for running a set program.
myNumber = oo;
ins = 0;
parseString( input );
time = millis() + timeStep;
disable = false;
genome = input;
}
void parseString( String in ) {
instructions = new int[in.length()];
for ( int j = 0; j < in.length(); j++ ) {
instructions[j] = int( in.charAt(j) - '0' );
}
}
void report() {
scores[myNumber] = dist( x, y, goalX, goalY ) + genome.length(); // Experimental score formula - adds a small penalty for long strings.
//println( "Car #" + myNumber + " (" + genome + ") stopped at " + int( x ) + ", " + int( y ) + ". Score: " + scores[myNumber] );
if ( scores[myNumber] < gbScore ) {
gbScore = scores[myNumber];
gbCar.x = x;
gbCar.y = y;
gbCar.z = z;
gbCar.k = k;
gbCar.genome = genome;
}
countDoneCars++;
// I know it's mean, but move the cheese if one gets way close...
// if ( scores[myNumber] < 10 ) {
// goalX = random(width);
// goalY = random(height);
// //println( " SOMEONE GOT THE CHEESE!!!" );
// }
//cars.remove(0);
}
void go() {
if ( millis() > time && !disable) {
time = millis() + timeStep;
if ( ins < instructions.length ) {
int i = instructions[ins++];
switch( i ) {
case 0:
// Do nothing.
break;
case 1:
a = !a;
break;
case 2:
b = !b;
break;
case 3:
c = !c;
break;
default:
//println( "Bum instruction: " + i );
break;
}
}
else { // Terminate run.
a=b=c=false;
v=0;
disable = true;
report();
}
}
// Car movement systems follow.
z+=(a?-.1:0)+(b?.1:0);
v+=(c?.1:0);
x=(x+width+v*cos(z))%width;
y=(y+height+v*sin(z))%height;
v*=.99;
render();
}
void render() {
pushMatrix();
translate(x, y);
rotate(z);
noStroke();
fill(k);
if ( myNumber==-1) fill(255, 0, 0);
rect(-10, -10, 20, 20);
stroke(0);
noFill();
triangle(-8, -8, 7, 0, -8, 8);
popMatrix();
}
}

GoToLoop

Re: Adding in acceleration and momentum

2 months ago

It's kinda game of life of cars!

ekapalka

Re: Adding in acceleration and momentum

2 months ago

Wow... I don't think I can top that... I've been working on this for a while, and here's an update:

import java.awt.AWTException;
import java.awt.Robot;
Robot robot;
float turn;
boolean SOOPASPEED;
int fullspeed = 6;
int regspeed = 1;
PVector pos;
PVector velocity = new PVector(0, 0); // initially, you're not moving.
void setup() {
size(displayWidth, displayHeight, P2D);
noCursor();
smooth();
fill(255);
textAlign(LEFT, TOP);
textSize(30);
rectMode(CENTER);
robot = makeRobot();
pos = new PVector(width / 2, height / 2);
}
void draw() {
background(255);
fill(0);
drawPlayer();
updatePosition();
}
void drawPlayer() {
pushMatrix();
translate(pos.x, pos.y);
rotate(turn);
noFill();
strokeWeight(4.0);
stroke(0);
rect(0, 0, 24, 40);
popMatrix();
}
void updatePosition() {
PVector v = velocity.get();
v.rotate(turn);
if (SOOPASPEED) {
pos.add(PVector.mult(v, fullspeed));
}
else {
pos.add(v);
}
wrap(pos);
}
void mouseMoved() {
turn += 0.0025 * constrain(mouseX - width / 2, -100, 100);
robot.mouseMove(width / 2, height / 2);
}
void wrap(PVector p) {
if (p.x > width) {
p.x = 0;
}
else if (p.x < 0) {
p.x = width;
}
if (p.y > height) {
p.y = 0;
}
else if (p.y < 0) {
p.y = height;
}
}
Robot makeRobot() {
try {
return new Robot();
}
catch (AWTException e) {
e.printStackTrace();
}
return null;
}
boolean sketchFullScreen() {
return true;
}
void keyPressed() {
if (key == 'a' || key == 'A') {
velocity.x -= regspeed;
}
else if (key == 'd' || key == 'D') {
velocity.x += regspeed;
}
else if (key == 's' || key == 'S') {
velocity.y += regspeed;
}
else if (key == 'w' || key == 'W') {
velocity.y -= regspeed;
}
else if (key == CODED && keyCode == SHIFT) {
SOOPASPEED = true;
}
}
void keyReleased() {
if (key == 'a' || key == 'A') {
velocity.x += regspeed;
}
else if (key == 'd' || key == 'D') {
velocity.x -= regspeed;
}
else if (key == 's' || key == 'S') {
velocity.y -= regspeed;
}
else if (key == 'w' || key == 'W') {
velocity.y += regspeed;
}
else if (key == CODED && keyCode == SHIFT) {
SOOPASPEED = false;
}
}

It has a lot of issues, especially with momentum (it gets to a point and then never slows down). What I really wanted for momentum was very slight drifting. I'm not sure how to describe what I have right now... if you turn while being acted on by momentum alone, the momentum acts really weird (unlike all the fantastic examples I've seen here)...