Adding a delay between iterations in a for loop?

Programming Questions

wbottle

Adding a delay between iterations in a for loop?

in Programming Questions • 27 days ago

class Explosion {
// proprietes
float posX; // Position X du "centre" des explosions (le premier point de chaque courbe est le centre)
float posY; // Position Y du centre
int nbrCourbes; // Nombre de courbe dans l'explosion
ArrayList mesCourbes; // Arraylist qui contient mes courbes

    // constructeur
Explosion(float posX_, float posY_, int nbrCourbes_) {
    posX = posX_;
    posY = posY_;
    nbrCourbes = nbrCourbes_;

    mesCourbes = new ArrayList();

    // Creation des courbes dependamment du nombre demande en parametre
    float R = random(50, 255);
    float G = random(50, 255);
    float B = random(50, 255);
    for (int i = 0; i < nbrCourbes; i++) {
      mesCourbes.add(new Courbe(color(R, G, B)));
    }
}

// fonction
void afficher() {
    for (int i = 0; i < mesCourbes.size(); i++) {
      Courbe c = (Courbe) mesCourbes.get(i);
      pushMatrix();
      translate(posX, posY);
      rotate(radians(i));
      c.afficher();
      popMatrix();
    }
}
}

In my "afficher()" function, I'm trying to add a delay between the displaying of each curve (courbe). I can't seem to figure it out. I've tried millis() all day long with timestamps and whatnot, it just won't work. Basically, I want each of them to appear after the other instead of all of them at the same time when I call Explosion()'s afficher()

Replies(8)

GoToLoop

Re: Adding a delay between iterations in a for loop?

27 days ago

Processing works in a way that we create an animation frame-by-frame.
We draw 1 of the frames inside draw(). And at the end of it, Processing renders it to screen.
Also, callback function draw() behaves as a great loop itself.

The catch is, we don't see the drawing happening inside draw(). Only its final result!
If we want an animation to be seen, we gotta divide the whole process as frames.
So, rather than our own loop, we gotta use draw() as the loop itself!

An online example of fireworks simulation:
http://studio.processingtogether.com/sp/pad/export/ro.9Q6oRai8-41WJ/latest

wbottle

Re: Adding a delay between iterations in a for loop?

27 days ago

Thank you for your reply!

In other words, I'm boned?

PhiLho

Re: Adding a delay between iterations in a for loop?

27 days ago

Non change, just little improvements:

class Explosion {
// proprietes
float posX; // Position X du "centre" des explosions (le premier point de chaque courbe est le centre)
float posY; // Position Y du centre
int nbrCourbes; // Nombre de courbes dans l'explosion
ArrayList<Courbe> mesCourbes; // Arraylist qui contient mes courbes
// constructeur
Explosion(float posX_, float posY_, int nbrCourbes_) {
posX = posX_;
posY = posY_;
nbrCourbes = nbrCourbes_;
mesCourbes = new ArrayList<Courbe>();
// Creation des courbes dependamment du nombre demande en parametre
float R = random(50, 255);
float G = random(50, 255);
float B = random(50, 255);
for (int i = 0; i < nbrCourbes; i++) {
mesCourbes.add(new Courbe(color(R, G, B)));
}
}
// fonction
void afficher() {
for (Courbe c : mesCourbes) { // Just show off of the foreach form of loop
pushMatrix();
translate(posX, posY);
rotate(radians(i));
c.afficher();
popMatrix();
}
}
}

Improvement: progressively display the curves:

class Explosion {
// proprietes
float posX; // Position X du "centre" des explosions (le premier point de chaque courbe est le centre)
float posY; // Position Y du centre
int nbrCourbes; // Nombre de courbes dans l'explosion
ArrayList<Courbe> mesCourbes; // Arraylist qui contient mes courbes
int courbesAffichees;
// constructeur
Explosion(float posX_, float posY_, int nbrCourbes_) {
posX = posX_;
posY = posY_;
nbrCourbes = nbrCourbes_;
mesCourbes = new ArrayList<Courbe>();
// Creation des courbes dependamment du nombre demande en parametre
float R = random(50, 255);
float G = random(50, 255);
float B = random(50, 255);
for (int i = 0; i < nbrCourbes; i++) {
mesCourbes.add(new Courbe(color(R, G, B)));
}
}
// fonction
void afficher() {
if (courbesAffichees >= nbrCourbes) {
return; // Explosion finie
}
for (int i = 0; i < courbesAffichees; i++) {
Courbe c = mesCourbes.get(i);
pushMatrix();
translate(posX, posY);
rotate(radians(i));
c.afficher();
popMatrix();
}
courbesAffichees++;
}
}

If it is too fast, it would need indeed to use millis() to delay the incrementation.

class Explosion {
// proprietes
float posX; // Position X du "centre" des explosions (le premier point de chaque courbe est le centre)
float posY; // Position Y du centre
int nbrCourbes; // Nombre de courbes dans l'explosion
ArrayList<Courbe> mesCourbes; // Arraylist qui contient mes courbes
int courbesAffichees;
int dernierTemps;
static final int DELAY = 500; // 500 ms entre deux mises à jour
// constructeur
Explosion(float posX_, float posY_, int nbrCourbes_) {
posX = posX_;
posY = posY_;
nbrCourbes = nbrCourbes_;
mesCourbes = new ArrayList<Courbe>();
// Creation des courbes dependamment du nombre demande en parametre
float R = random(50, 255);
float G = random(50, 255);
float B = random(50, 255);
for (int i = 0; i < nbrCourbes; i++) {
mesCourbes.add(new Courbe(color(R, G, B)));
}
dernierTemps = millis();
}
// fonction
void afficher() {
if (courbesAffichees >= nbrCourbes) {
return; // Explosion finie
}
for (int i = 0; i < courbesAffichees; i++) {
Courbe c = mesCourbes.get(i);
pushMatrix();
translate(posX, posY);
rotate(radians(i));
c.afficher();
popMatrix();
}
if (millis() - dernierTemps > DELAY) {
courbesAffichees++;
dernierTemps = millis();
}
}
}

Note: all this is untested...
Note about static final: static means it is the same value for all instances of the class, final means it is a constant, the value cannot be changed.

wbottle

Re: Adding a delay between iterations in a for loop?

27 days ago

Thank you PhiL, that does make sense.

The only issue is that c. becomes undefined, hence I'm not sure how to call each of the "Courbe"'s afficher() functions.

PhiLho

Re: Adding a delay between iterations in a for loop?

27 days ago

Ah, I forgot a line in the last listing. Restored it above.

wbottle

Re: Adding a delay between iterations in a for loop?

27 days ago

Thank you SO much!

wbottle

Re: Adding a delay between iterations in a for loop?

27 days ago

I tried stopping my curves from disappearing once we reach the desired amount (without removing my background(0) from draw()) but I can't seem to figure that out either.

I tried replacing the return; in courbesAffichees >= nbrCourbes by something along the lines of mesCourbes.remove(0); then courbesAffichees--; but that didn't seem to work, I get an out of bounds.

Thoughts?

PhiLho

Re: Adding a delay between iterations in a for loop?

26 days ago

I would need a simple sketch wrapping your class above and providing the missing class, it is hard to tell in abstract like that. Simplify your sketch if it is complex, just to show this effect (eg. on mouse click).

Top Reply