About Iterators on objects

Programming Questions

akenfqs

in Programming Questions • 2 years ago

Hi ! I'm back again with my little script. As i mentioned here :

I try to create an animation that I saw few month earlier on a website : you click somewhere, a circle begin to grow, then you click somewhere else, another circle begin to grow and when they meet, a sound is made.

My problem was with the circles position, then it was with instances generation, but before being lost, i found this topic who helped me to create objects automatically : http://processing.org/discourse/yabb2/YaBB.pl?num=1212683829

It uses Iteration without using hashmap, it was perfect for me since i needed to create multiples instances of the same animated class by clicking. BUT now I have to setup the collision to make the circles inverse theyre growth when hitting the others circles. With the iteration presented in the code below (I withdrawn sound code parts for you all to test it) i don't know how to retrieve informations about the objects created to calculate distances to set up any collision function, could you help me ?

Here is the code :

Vector cercles;
void setup() {
size(400, 400);
ac = new AudioContext();
cercles = new Vector();
}
void draw() {
background(192, 64, 0);
Iterator i = cercles.iterator();
while (i.hasNext())
{
Cercle cercle = (Cercle)i.next();
cercle.display();
cercle.drive();
}
}
void mousePressed()
{
cercles.add(new Cercle(1,1,0));
}
class Cercle {
// data
float startX, startY;
float largeur;
float hauteur;
float swap;
float vitesse;
// constructor
Cercle (float largeur, float hauteur, float swap){
startX = mouseX;
startY = mouseY;
vitesse = 0.7;
}
// fonctions
void display() {
ellipseMode(CENTER);
ellipse(startX,startY,largeur,hauteur);
}
void drive() {
if(largeur < 60)
{
if(swap == 0)
{
largeur+=vitesse;
hauteur+=vitesse;
}
else
{
largeur-=vitesse;
hauteur-=vitesse;
if(largeur <= 1)
{ swap = 0; }
}
}
if(largeur >= 60)
{
swap = 1;
largeur-=vitesse;
hauteur-=vitesse;
}
}
}

Thanks

Replies(16)

tfguy44

Re: About Iterators on objects

2 years ago

You're going to have to check every circle against every other circle.

You can do this by iterating through the Vector of circles, and for each one, iterate through the vector again (making sure you're looking at different circles, of course) and checking it they overlap.

Remember: Two circles overlap if the distance between their centers is less than the sum of their radii.

akenfqs

Re: About Iterators on objects

2 years ago

You can do this by iterating through the Vector of circles, and for each one, iterate through the vector again (making sure you're looking at different circles, of course) and checking it they overlap.

I knew that :p I ask how to do the thing since I don't know how to access and manage each circle separately

akenfqs

Re: About Iterators on objects

2 years ago

Nobody can give me some clues ? x_X

PhiLho

Re: About Iterators on objects

2 years ago

You already do that in draw(), you know?

I would advise to use the moderner ArrayList instead of the legacy Vector.

ArrayList<Cercle> cercles = new ArrayList<Cercle>();
void draw() {
background(192, 64, 0);
for (Cercle cercle : cercles)
{
cercle.display();
cercle.drive();
}
}

akenfqs

Re: About Iterators on objects

2 years ago

I saw somewhere that an ArrayList was maybe better than a Vector, it didn't say why.

Also, I'm a newbie :/ you don't help me by just dropping some code without explaining why I am supposed to use it.

And what do you mean by " You already do that in draw(), you know?" ?

thomas.di..

Re: Re: About Iterators on objects

2 years ago

ArrayList is almost the same as Vector only that a Vector is has synchronized methods (so its optimized for multithreading) and an ArrayList has not (which can be faster if you dont use multiple threads). also, you usually see an ArrayList much more often in code-examples.

The example phi.lho postet is just another way to iterate thorugh a list:
http://www.java-tips.org/java-se-tips/java.lang/the-enhanced-for-loop.html

ArrayList:
http://processing.org/reference/ArrayList.html
http://download.oracle.com/javase/6/docs/api/java/util/ArrayList.html (for all ArrayList methods)

PhiLho

Re: About Iterators on objects

2 years ago

Vector is old and synchronized, so slower. Even if it makes no difference in most sketches, it is best to just avoid it. For multithreading, there are even better structures to use today.

" you don't help me by just dropping some code without explaining why I am supposed to use it"
I show better practices that those you use, and a newbie should be able to search the reference, eg. to find the links Thomas kindly searched for you... Although I fear the ArrayList reference in Processing is badly outdated, giving the old syntax (I shown the Java 1.5 syntax which is now supported by Processing) and giving a reference to the old documentation (still on Sun's site...).

" And what do you mean by " You already do that in draw(), you know?" ?"
You asked " how to access and manage each circle separately", I said you already did that in the first code you shown, and just shown a better alternative.

Note: back to the subject of the thread, the foreach loop (enhanced for loop) just uses an iterator, but it is hidden by the syntax.

akenfqs

Re: About Iterators on objects

2 years ago

Hi all, thank you for the answers :)

So Phi.lho your syntax for the ArrayList didn't work so I tried things around with the links THomas gived me and it worked \o/

In fact I did'nt understand at all the way the Vector works but with ArrayList it was way much clear to me !

After, I began to seek for simple collision realisations over the internet to achieve my goal (I learn while I copy ^^)

And this thing helped me a lot : http://www.berio.alg-a.org/Multiple-ball-collision

Now I am finishing and I will give you the result when the thing will be perfect ;)

PhiLho

Re: About Iterators on objects

2 years ago

" So Phi.lho your syntax for the ArrayList didn't work"
What version of Processing do you have?

akenfqs

Re: About Iterators on objects

2 years ago

The last one (1.5 ?)

PhiLho

Re: Re: About Iterators on objects

2 years ago

Well, it should work. As you can see, Thomas used it successfully.

akenfqs

Re: About Iterators on objects

2 years ago

Anyway i stuck with something : I want to be able to create circles into other circles so it have to detect collision but in different manner (the dist(); is no longuer usefull as for the classic collision detection). I'm getting slowly mad with that

thomas.di..

Re: Re: About Iterators on objects

2 years ago

the following code lets you generate new circles on mouseReleased() and animates their radius.
if two circles collide, they change their expansion direction.
this version only works, if a new circle is created outside of every other circle.

ArrayList<Circle> circles = new ArrayList<Circle>();
void setup(){
size(500,500);
}
void draw(){
background(255);
// update the circles animation direction
for( Circle c : circles)
c.updateDir(circles);
// update the circles radius
for( Circle c : circles)
c.update();
// draw all circles
fill(200);
for( Circle c : circles)
c.draw();
}
void mouseReleased(){
circles.add(new Circle(mouseX, mouseY, 0, random(1, 2)) );
}
class Circle{
float x_, y_, r_, anim_speed_;
Circle(float x, float y, float r, float anim_speed){
x_ = x;
y_ = y;
r_ = r;
anim_speed_ = anim_speed;
}
void updateDir(ArrayList<Circle> circle_list){
for(Circle c : circle_list){
if(c == this) continue;
if( distanceTo(c) <= (abs(c.r_) + abs(r_))/2f)
anim_speed_ = -anim_speed_;
}
}
void update(){
r_ += anim_speed_;
}
float distanceTo(Circle c){
float disx = c.x_ - x_;
float disy = c.y_ - y_;
return sqrt(disx*disx + disy*disy);
}
void draw(){
ellipse(x_, y_, r_, r_);
}
}

ps. just recognized, there is be a problem at a certain number of collisions

akenfqs

Re: About Iterators on objects

2 years ago

I did something similar but with more code but without any bug :p but i still have to find how to make collisions when a circle is made inside another circle x_X

ArrayList cercles;
void setup() {
size(400, 400);
smooth();
cercles = new ArrayList();
}
void draw() {
background(100, 150, 175);
if(cercles.size()>0)
{
for (int i = 0; i < cercles.size(); i++) {
Cercle cercle = (Cercle) cercles.get(i);
cercle.display();
if(cercles.size()==1)
{ cercle.grow(); }
}
}
if(cercles.size()>1){
for(int j=0; j<cercles.size(); j++){
Cercle cercle1 = (Cercle) cercles.get(j);
for(int k=j+1; k<cercles.size(); k++){
Cercle cercle2 = (Cercle) cercles.get(k);
cercle1.intersect(cercle2);
}
}
}
}
void mousePressed()
{
cercles.add(new Cercle());
}
class Cercle {
// data
float startX, startY;
float r;
float vitesse;
float degrow;
float grow;
// constructor
Cercle (){
r = 1;
startX = mouseX;
startY = mouseY;
vitesse = 0.5;
degrow = 0;
grow = 0;
}
// fonctions
void display() {
stroke(0,0,0,150);
noFill();
ellipse(startX,startY,r*2,r*2);
if(grow == 1)
{ r += vitesse; }
else
{ r -= vitesse; }
}
void grow() {
grow = 1;
}
void intersect(Cercle _b) {
Cercle b = _b;
float distance = dist(startX,startY,b.startX,b.startY);
if (distance <= r + b.r) {
grow = 0;
b.grow = 0;
degrow = 1;
b.degrow = 1;
}
else {
if(r > 0)
{
if(degrow == 1)
{ grow = 0; }
else
{ grow = 1; }
}
else
{
grow = 1;
degrow = 0;
}
if(b.r > 0)
{
if(b.degrow == 1)
{ b.grow = 0; }
else
{ b.grow = 1; }
}
else
{
b.grow = 1;
b.degrow = 0;
}
}
}
}

akenfqs

Re: About Iterators on objects

2 years ago

Weird, it indicates " last response by phi.lho on 09-Jun" but the last is mine :p