3d tree-growth simulator

asimes

Re: 3d tree-growth simulator

1 year ago

Just an on the fly idea would be to create an ArrayList that stores distances. If any of those distances gets beyond a certain point then they spawn two new growing lines who's distances also have to be stored. The most annoying things would be always setting the starting point of new growing lines to be based on their "parent" and only having distances spawn a new point once after they pass a threshold distance (can be done by having an ArrayList that stores booleans match the distance ArrayList).

Konstanti..

Re: Re: 3d tree-growth simulator

1 year ago

I will have a list of objects for sure, but...

I think a list of distancess would not be enough (I would have to do all the calculations of growth outside the list)

I plan to make a list of "branches". Each branch is an instance of a class, and it grows from another branch, or from point zero. Lets say that point zero provides an energy of 100. This energy goes to the Main branch. Then the branch splits into two new branches. Lets suppose that the one branch has a 30 degree divergence from the Main branch, and the other branch has a 60 degree divergence from the Main branch. Well.. I aint got the formula yet, but lets say that the 30 degree branch will get 70% of the energy, and the 60 degree branch will get the remaining 30%. This means that branches than are more vertical (or more collinear to their parents) will get more of their parents' energy (and hence grow more rapidly). Inorder to do all this calculation I should definately have a class named branch, that stores the two points (Base_Point and End_Point), and the divergence from the parent branch. Then, when we calculate the energy the branch takes from its parent, we can apply some growth to it every cycle..

Hope it doesnt get TOO complicated yet...

I will have some code soon.

Konstanti..

Re: 3d tree-growth simulator

1 year ago

So far I have set up a 3d scene with a grid,

and done some stuff with organizing things in classes.

I have stumbled, though, on this problem:

Lets say I have two points.

p1(10,10,20) and p2(20,30,50)

I can calculate the distance between them using vectors like that:

PVector v1,v2;

v1 = new PVector(10,10,20);

v2 = new PVector(20,30,50);

float d = pvector.dist(v1,v2);

I can also calculate the angle between them using this code:

float a = PVector.angleBetween(v1,v2);

But what I realy want to do is the reverse of that.

Given one point p1(10,10,20), one length L = 10, and two angles a1, a2 (where a1 = the divergence angle from the Z axis, and a2 is the rotation angle around the Z axis), I want to calculate the next point.

Is there any easy way to do that? Or do I have to use math all the way?

Any response to that would be greatly appreciated.

asimes

Re: 3d tree-growth simulator

1 year ago

You may have to look into spherical positioning or something else like it: http://en.wikipedia.org/wiki/Spherical_coordinate_system

Here is a sketch I made of how to place a point (represented by a sphere) based on another point. Maybe it will be useful for you:

float rad = 200;
float theta = HALF_PI;
float phi = HALF_PI;
void setup() {
size(800, 600, P3D);
}
void draw() {
//theta += TWO_PI/1000;
//phi += TWO_PI/100;
float x = cos(phi)*sin(theta)*rad;
float y = cos(theta)*rad;
float z = sin(phi)*sin(theta)*rad;
background(255);
translate(width/2, height/2);
noFill();
sphere(rad);
translate(x, y, z);
fill(255, 0, 0);
sphere(20);
}

On a side note, I don't think I understand your energy idea. Is it just a way to have distances that are more vertical grow at a faster pace?

Konstanti..

Re: 3d tree-growth simulator

1 year ago

Ok, so theta is the divergence angle, and phi is the rotation angle.

Thanks for the example^^ and the link.

As for the energy idea, it is something like that, but the relation of verticality versus energy flow might give different "species" of trees. I have not tested it yet, though.

For example a cypress or a spruce tree

http://en.wikipedia.org/wiki/Spruce

has a vertical trunk and the branches are almost horizontal. Considering the trunk as a series of vertical branches, they get more energy and so the tree grows in an elongated shape.

While if the relation was reversed, I would have something like a very short and wide-spread shrub, where the horizontal branches are the ones that expand the most.

Anyway... it is abit too early for that anyway.

For the time being I have to complete the first part (where branches are growing from other branches...)

benja

Re: 3d tree-growth simulator

1 year ago

I'm not completly sure if that is what you had in mind, but to create a random vector that has a certain angle between it and a given vector, you just have to rotate it around a random axis, that is perpendular to your first vector.
(I think it sounds easy, but was not that obvios to me at first).

import toxi.geom.Vec3D;

Vec3D v1, v2, axis;
float angle = PI/4;

void setup() {
size(400, 400, P3D);
v1 = new Vec3D(0, -200, 0);
}

void draw() {
// create a random vector that is not parallel v1
boolean isParallel = true;
while (isParallel) {
axis = Vec3D.randomVector();
isParallel = (axis.dot(v1)==0) ? true : false;
}

// create perpendular axis
axis.cross(v1);

// rotate
v2 = v1.copy().rotateAroundAxis(axis, angle);

background(255);
translate(width/2, height/1.5);
rotateY(map(mouseX, 0, width, 0, TWO_PI));
stroke(255, 0, 0);
line(0, 0, 0, v1.x, v1.y, v1.z);
stroke(0, 0, 255);
line(0, 0, 0, v2.x, v2.y, v2.z);

angle = map(mouseX, 0, width, 0, PI);
}

I played around with your idea and must admit, this part was the most difficult for me.
I would go for nested classes, so that each branch has an array of child-branches and manages their update/display functions.

Konstanti..

Re: 3d tree-growth simulator

1 year ago

As for the vector technique, we actually need to have the endpoint coordinates of any branch at any time, because this is the point where the next branch will grow from. And it changes all the time, because even after a branch has grown from another, the "parent" branch continues to grow. So i think that rotating the vector (which could be done with gl.Rotatef() or rotateX, Y, Z.. and so on) wil not do.

I could not test your example because I dont have the toxi library.

But I think it is a case like the one above^^.

This is what i have done so far:

Three branches growing from a base point.

Nothing special, but i have set up some stuff with classes.

There is the Tree class which handles an ArrayList of Branches.

Also there is an ArrayList of Trees becausee later we might have more trees in the same scene.

///////////////////////////////
//TREE_GROW_3D
///////////////////////////////
import javax.media.opengl.*;
import processing.opengl.*;
float camx, camy, camz, tarx, tary, tarz, upx, upy, upz;
ArrayList trees;
//SETUP STUFF
void setup(){
size(1280, 720, P3D); //720p hi def
frameRate(60);
//set camera
camx = 150; camy = 150; camz = 100;
tarx = 0; tary = 0; tarz = 0;
upx = 0; upy = 0; upz = -1;
trees = new ArrayList();
trees.add(new Tree(0,0,0));
}
void draw(){
background(20);
camera(camx, camy, camz, tarx, tary, tarz, upx, upy, upz);
stroke(0,0,0);
noFill();
draw_grid();
// draw tree
Tree tree = (Tree) trees.get(0);
tree.tCalc();
tree.tDraw();
}
void draw_grid(){
float i = 0;
int gridExtents = 200;
stroke(10,60,10);
beginShape(LINES);
for (i=-gridExtents/2; i <=gridExtents/2; i+= 5){
vertex(-gridExtents/2,i,0); vertex(gridExtents/2,i,0);
vertex(i,-gridExtents/2,0); vertex(i,gridExtents/2,0);
}
endShape();
}
/////////////////////////////////////////////////////
// Class Branch
// This class represents a branch of the tree
/////////////////////////////////////////////////////
class Branch{
int generation = 0; // generation number
int bTag = 0; // unique code for this branch
int parentTag = 0; // unique code for parent brancch
float baseX, baseY, baseZ;
float endX, endY, endZ;
float angDiv, angRot; // angle of divergence, angle of rotation
float bEnergy, bGrowthStep, bLength;
// create class
Branch(float inbX, float inbY, float inbZ,
float inAngDiv, float inAngRot,
float inEnergy){
baseX = inbX; baseY = inbY; baseZ = inbZ; // base position
angDiv = inAngDiv; angRot = inAngRot;
endX = 20; endY = 20;endZ=30;
bEnergy = inEnergy;
bLength = 0.1;
endZ = baseZ + bLength * cos(angDiv);
endX = baseX + bLength * sin(angRot);
endY = baseY + bLength * cos(angRot);
}
void grow(){
bLength += 0.1;
endZ = baseZ + bLength * cos(angDiv);
endX = baseX + bLength * sin(angRot);
endY = baseY + bLength * cos(angRot);
}
}
/////////////////////////////////////////////////////
//Class Tree
//This class handles the branches
/////////////////////////////////////////////////////
class Tree{
ArrayList branches;
float baseX, baseY, baseZ;
//create tree
Tree(float inX, float inY, float inZ){
baseX = inX; baseY = inY; baseZ = inZ;
branches = new ArrayList();
branches.add(new Branch(0,0,0,
45,105,
100));
branches.add(new Branch(0,0,0,
55,305,
100));
branches.add(new Branch(0,0,0,
5,205,
100));
}
void tCalc(){ //calculate stuff
for (int i = branches.size()-1; i >= 0; i--) {
Branch branch = (Branch) branches.get(i);
branch.grow(); //grow each branch
}
}
void tDraw(){ // draw the tree
stroke(180,130,50);
beginShape(LINES);
//rotateZ
for (int i = branches.size()-1; i >= 0; i--) {
Branch branch = (Branch) branches.get(i);
vertex(branch.baseX,branch.baseY,branch.baseZ);
vertex(branch.endX,branch.endY,branch.endZ);
}
endShape();
}
}

I am not so familiar with the nested classes technique.

Can you come up with an example of how we could use it here?

benja

Re: 3d tree-growth simulator

1 year ago

The idea is to create only one branch.
When the length of this branch reaches a certain value, it generates a couple of new child-branches.
Each branch manages its children by itself. Because the branch knows, where it ends, its easy to update the start-position of its children.

Example:

import toxi.geom.Vec3D;

Branch tree;

void setup() {
size(1000, 700, P3D);

stroke(255, 50);
tree = new Branch(new Vec3D(0, -1, 0), 5);
tree.start = new Vec3D(0, 0, 0);
}

void draw() {
background(0);
translate(width/2, height-10);
rotateY(map(mouseX, 0, width, 0, TWO_PI));

tree.update();
tree.display();
}

class Branch {
float spltLength = 35;
int numChildren = 6;
float maxAngle = PI/2;
float energy;

Vec3D start;
Vec3D end;
Vec3D direction;
Branch[] children;

Branch( Vec3D direction, float energy) {
    this.direction = direction;
    this.energy = energy;
}

void update() {
    // grow
    float factor = 1 + energy/(0.5*sq(direction.magnitude()));
    direction = direction.scale(factor);
    end = start.add(direction);

    // if splitLength is reached, create children and update them
    if (direction.magnitude() >= spltLength) {
      // create child-branches if they don't exist
      if (children == null) {
        createChildren();
      }
      for (int i =0; i<children.length; i++) {
        children[i].start = end;
        children[i].update();
      }
    }
}

void createChildren() {
    children = new Branch[numChildren];
    for (int i = 0; i<numChildren; i++) {

      // this is not so elegant, there may be slick solution for it
      Vec3D axis = new Vec3D();
      boolean isPerpendicular = false;
      // find a perpendicular vector
      while (!isPerpendicular) {
        axis = Vec3D.randomVector();
        if (direction.dot(axis)!=0) {
          isPerpendicular = true;
        }
      }
      axis.cross(direction);
      //rotate vector
      Vec3D dir = direction.copy().rotateAroundAxis(axis, random(-maxAngle, maxAngle));
      dir.normalize();
      // calculate energy
      float en = map(abs(dir.angleBetween(direction, true)), 0, maxAngle, energy, 0);
      children[i] = new Branch(dir, en);
    }
}

void display() {
    line(start.x, start.y, start.z, end.x, end.y, end.z);
    if (children == null) {
      point(end.x, end.y, end.z);
    }
    else {
      for (int i = 0; i<children.length; i++) {
        children[i].display();
      }
    }
}
}

I used the toxiclibs-library because Vec3D has more functions than PVector, rotateAroundAxis() for example.

Konstanti..

Re: 3d tree-growth simulator

1 year ago

I think the "void createChildren()" function is very important for this example.

The code you have written does the work for now, but I'm trying to find a better way to do it. Perhaps If we could extract the Theta and the Phi values from the "direction" vector, then we could use them to create the new vector (for the child branch) making two rotations (one that is relative to Theta and one to Phi).

This would also give more flexibility for many possible scenarios of angular relationships between the two branches, or other parameters which might affect the branch's direction. For example, there could be an outside attractor, such as "Light" that affects the branches' growth. Or there could be a more specific relationship between the parent branch and the children.

For example:

-At some Length the branch creates one child that is almost collinear.

-This is actually a branch growth.

-At bigger Length the branch creates a leaf from the same spot. (Green branch, produces no children).

-And at even bigger Lenght, the branch creates a child with a Perpendicular relationship. (side branch).

Well, too much theory... the "direction" problem comes first.

I have been reading the documentation for vec3d http://toxiclibs.org/docs/core/toxi/geom/Vec3D.html and I have not yet found an easy solution, but even if there is none, some math will do the work.

Konstanti..

Re: 3d tree-growth simulator

1 year ago

Well, I think that this>> http://toxiclibs.org/docs/core/toxi/geom/Vec3D.html#headingXY()

might do the work for getting the needed angles from the vector.

So the idea is:

float Phi = direction.headingYZ();

float Theta = direction.headingXY();

Vec3D dir = new Vec3D(1,0,0);

dir.RotateAroundAxis(Z_AXIS, Phi+random(-maxAngle, maxAngle));

dir.RotateAroundAxis(Y_AXIS, Theta+random(-maxAngle, maxAngle));

Have not tested this code yet, but I think it might work.

Konstanti..

Re: Re: 3d tree-growth simulator

1 year ago

Actually I have made this piece of code fot the "create_children" function.

It gives some interestingly problematic results.

void createChildren() {
children = new Branch[numChildren];
for (int i = 0; i<numChildren; i++) {
Vec3D dir = new Vec3D(1,0,0); //zero rotation around all axes
float angZ = direction.headingXY(); //get the rotation around Z axis
dir.rotateZ(angZ+random(-maxAngle, maxAngle));
float angY = direction.headingXZ(); //get the rotation around Y axis
dir.rotateY(angY+random(-maxAngle, maxAngle));
dir.normalize();
float en = map(abs(dir.angleBetween(direction, true)), 0, maxAngle, energy, 0);
children[i] = new Branch(dir, en);
}
}

I'm trying to pinpoint the problem, whether it is on the rotation functions, or on the energy settings...

Anyway, be back soon.

benja

Re: 3d tree-growth simulator

1 year ago

Hi,

the issue is that if you do two rotations with an angle between -maxAngle and maxAngle, the resulting angle might be bigger than maxAngle. The map()-function assumes an angle between 0 and maxAngle, and brings strange results if that is not the case. You could limit the angle for example by using min().

float angle = min(maxAngle, abs(dir.angleBetween(direction, true)));
float en = map(angle, 0, maxAngle, energy, 0);

Konstanti..

Re: 3d tree-growth simulator

1 year ago

Allright, I just corrected it.

I used another method to correct the range, but the result is good now.

here is the full code:

(I have made some other alterations as well, but mainly about appearance)

import toxi.geom.*;
import toxi.processing.*;
Branch tree;
void setup() {
size(1000, 700, P3D);
stroke(255, 50);
tree = new Branch(new Vec3D(-0.02, -1, 0.05), 8);
tree.start = new Vec3D(0, 0, 0);
}
void draw() {
background(0);
translate(width/2, height+200,-500);
rotateY(map(mouseX, 0, width, 0, 4*PI));
tree.update();
tree.display();
}
class Branch {
float spltLength = 15;
int numChildren = 4;
float maxAngle = PI/1.8;
float energy;
Vec3D start;
Vec3D end;
Vec3D direction;
Branch[] children;
Branch( Vec3D direction, float energy) {
this.direction = direction;
this.energy = energy;
}
void update() {
// grow
float factor = 1 + energy/(0.5*sq(direction.magnitude()));
direction = direction.scale(factor);
end = start.add(direction);
// if splitLength is reached, create children and update them
if (direction.magnitude() >= spltLength) {
// create child-branches if they don't exist
if (children == null) {
createChildren();
}
for (int i =0; i<children.length; i++) {
children[i].start = end;
children[i].update();
}
}
}
void createChildren() {
children = new Branch[numChildren];
for (int i = 0; i<numChildren; i++) {
//get the rotation of "direction" around the Y axis
float angY = direction.headingXZ();
//create a copy and rotate until it's parallel to the XZ plane
Vec3D directionCopy = direction.copy().rotateY(-angY);
//get the rotation of "directionCopy" around the Z axis
float angZ = directionCopy.headingXY();
Vec3D dir = new Vec3D(1,0,0); //zero rotation around all axes
// I added a circular factor to limit the angles so the 3Dangle does not exceed the maxAngle
float rnd = random(-PI,PI);
float factorZ = sin(rnd);
float factorY = cos(rnd);
dir.rotateZ(angZ+random(-maxAngle, maxAngle)*factorZ);
dir.rotateY(angY+random(-maxAngle, maxAngle)*factorY);
dir.normalize();
float en = map(abs(dir.angleBetween(direction, true)), 0, maxAngle, energy,0);
children[i] = new Branch(dir, en);
}
}
void display() {
//stroke(50,255,50,int(direction.magnitude()*2));
strokeWeight(int(direction.magnitude()/20)+1);
if (children == null) {
//point(end.x, end.y, end.z);
stroke(0,255,0,100);
beginShape(LINES);
vertex(start.x, start.y, start.z);vertex(end.x, end.y, end.z);
endShape();
}
else {
stroke(255,100,0,100);
beginShape(LINES);
vertex(start.x, start.y, start.z);vertex(end.x, end.y, end.z);
endShape();
for (int i = 0; i<children.length; i++) {
children[i].display();
}
}
}
}

Although this is working fine,

I have noticed that the 4 first branches are always (almost) on the same 3d plane.

This is due to the fact that "maxAngle" applies to the rotation around the Y axis, as well.

Which means that another "rule" is needed as to how branches come out of branches.

It is not only a math problem, it is also a problem of following a realistic simulation of growth.

p.s. Thanks alot for your help so far.

monkstone

Re: Re: 3d tree-growth simulator

1 year ago

At this point you might start thinking what has been done before to simulate natural growth, particulary the work of Aristid Lindenmayer. Funnily enough I've just been hacking away on a pyprocessing sketch of a tree, see my blog. Or perhaps you really do want to plough a different furrow? I've yet to produce a 3d stochastic tree but I've made it easy to do so using my lsystems library (you could use RodTurtle to draw the branches).

Konstanti..

Re: 3d tree-growth simulator

1 year ago

Well, it is true that I have not done much research on the matter up to now. Thanks for the wiki-links.

"To plough a different furrow" is not my purpose, not unless the work can be done with a tool that exists. In fact I am very glad that it does. So... I will try your lsystems library for sure. I 'm wondering, though, if it can be used in this example, where the tree grows real-time... (might be a silly question?)

Is there any documentation on the library? (might be another silly question?)

monkstone

Re: Re: 3d tree-growth simulator

1 year ago

My library may not be exactly what you want for a real time system, though in principle there's no reason why you couldn't alter the number of iterations with time (and redraw the tree), see my 3D hilbert for example where you can step up or down the number of iterations. But other java lsystems eg this one already do present a tree real time (albeit a bit crudely for my taste). I haven't created too much documentation for my library, but there's plenty of examples included. Oops I lied I already did a stochastic tree see my blog, could be tarted up to use my RodTurtle (as truncated cone), with reducing length/radius as I did with my pyprocessing context sensitive plant. NB: in the original example the three rules had equal weight as the weighting has not been explicitly set. The code needed a bit of modifying for the most recent version of my library, not exactly what you want but, then I have feeling you original plan might be a bit ambitious (library was built for processing-2.0 so if you are using processing 1.5 the cones don't look right?).

import lsystem.*;
import lsystem.turtle.RodTurtle;
import lsystem.turtle.Turtle3D;
import lsystem.util.*;
Grammar grammar;
float distance = 400;
int depth = 4;
int theta = 21;
int phi = 40;
Turtle3D turtle;
ArcBall arcball;
// adjust length with generation/branch
float[] scaleFactor = {
0.7, 0.72, 0.75, 0.85, 0.9
};
void setup() {
size(800, 800, P3D);
smooth(8);
turtle = new RodTurtle(this);
arcball = new ArcBall(this, width/2, height * 0.8, width * 0.5);
arcball.constrain(Constrain.YAXIS);
setupGrammar();
noStroke();
}
void setupGrammar(){
grammar = new StochasticGrammar(this, "F"); // this only required to allow applet to call dispose()
grammar.addRule('F', "F[&+F]F>>[->F]>>[->F]>>[&F]", 2);
grammar.addRule('F', "F>[&+F]F[->F]>[->F]>[&F]", 1);
grammar.addRule('F', "F>>[&+F]>F[->F][->F][&F]", 1);
grammar.generateGrammar(depth);
distance *= pow(0.7, depth);
}
void draw() {
background(0);
lights();
translate(width/2, height * 0.8);
arcball.update();
render();
}
void render() {
translate(0, 50, 0); // center the plant empirically set looks OK to me
fill(0, 175, 0);
rotateX(PI / 2); // start with tree pointing up
lightSpecular(0, 204, 0);
specular(0, 255, 0);
shininess(1.0);
int count = 0;
CharacterIterator it = grammar.getIterator();
for (char ch = it.first(); ch != CharacterIterator.DONE; ch = it.next()) {
switch (ch) {
case 'F':
turtle.drawRod(distance, distance / 8, distance / (8 * scaleFactor[count]), count);
scale(scaleFactor[count]);
break;
case '-':
turtle.pitch(theta);
break;
case '+':
turtle.pitch(-theta);
break;
case '>':
turtle.roll(phi);
break;
case '<':
turtle.roll(-phi);
break;
case '&':
turtle.yaw(phi);
break;
// case '^':
// turtle.yaw(theta);
// break;
case '[':
pushMatrix();
break;
case ']':
popMatrix();
break;
default:
System.err.println("character " + ch + " not in grammar");
}
if (count < 4) {
count++;
}
}
}

Konstanti..

Re: 3d tree-growth simulator

1 year ago

Being completely ignorant (at the moment) of the theory behind this code (suppose it is Lsystems theory... lol), I can follow the flow of this example, except for the part of how the grammar class works. Is there any documentation on that? Every symbol is applied to an action (like pitch or roll), but how exactly do the different rules form a grammar?

I would like to get a better understanding the library tools, in general.

(library was built for processing-2.0 so if you are using processing 1.5 the cones don't look right?).

*I use processing 2.0 so everything works fine.

not exactly what you want but, then I have feeling you original plan might be a bit ambitious

The original plan is kind of vague. Mainly i just wanted to play abit with the matter. Though I am actually trying to create a useful tool in a way. I work on landscape architecture and very often i come up with the need of drawings or 3d models of plants. Very often the trees are added to drawings using photoshop, which is a very time-consuming way of working. Other times I have used 3d models of trees that are made of some thousands of polygons (usually 5 digits or more) which are cpu - gpu consuming. Also These two options are usually realistic as to their appearance, but not as to their scale.

So I hope that I could create a tool that produces realistic models of trees (as for their species, scale, and growth stage or age). I would not need them to be very fancy, but just to be close to reality as far as their structure and size is concerned.

This would, ofcourse, need an adjustment of the code with some real knowledge of these data for certain species of trees. But this would be the last stage, after the "tool" is formed.

Actually, now that I come to think of it, your example could do this job as it is now, apart from the fact that it does not cover the "leaves" part.

So the "real-time-growth" part is kind of out of the main goal, but it's fun...

Perhaps the ambitious part is that of the simulation of natural elements such as light or wind affecting the tree's growth, but I think that a branch-class aproach as is formed on the previous example can evolve to that. It would just perhaps start to be not-so-real-time, due to the low fps...

Thanks alot for taking the time to share your example and libraries, though...

I have a feeling it will lead to some good combination.

monkstone

Re: Re: 3d tree-growth simulator

1 year ago

Leaves can be added, you just need to create a "rule" for them, and a shape to go with it. The theory behind LSystems for plants is well covered in the excellent

The Algorithmic Beauty of Plants

see http://algorithmicbotany.org/papers/ scroll to bottom of page for the book. My library supports a three different grammars:-

A SimpleGrammar each character only has one substitution
A StochasticGrammar where if there is more than one substitution per character the one applied is determined based on "weighting" ie from its probability.
A ContextSensitive grammar where it is possible to supply a rule that only operates if the characters are in a certain sequence (this can be complicated, and to date I only support one direction of context at a time), although I do support the necessary ignores

The way my library works is it takes the starting string "axiom" and does the substitutions according to the rules and number of generations. The result is made available as a CharacterIterator, most characters are associated with some sort of action eg F draw, + rotate etc...

Konstanti..

Re: 3d tree-growth simulator

1 year ago

Getting back to the basics...

monkstone I have a very important question:

As i figured out, the turtle class in your example works by taking advantage of the pushMatrix() and popMatrix() technique, which actually lets us redefine a coordinate system in relation to the previous one. And so by using turtle.pitch, roll, yaw, you define way for each branch to rotate in relation to its previous one. Right so far?

This is the easiest way to handle multiple coordinate systems , but only on graphics level.

Supposing this could be applied to an example of nested classes (like the previous 3d tree example), do you think there could be a way to have local parameters translate into world parameters?

For example could we get the absolute XYZ of a branch's end point after we have "popped the matrix"?

If that is the case, then the translations and rotations of opengl could be used as a mathematical tool.

If not, well, I need to define a way to handle local spherical coordinate systems, which I already started coding, because I think that is the case.

If anyone else has any suggestion please share

monkstone

Re: Re: 3d tree-growth simulator

1 year ago

In theory at least modelX, modelY, modelZ should work, however the last time I tried it I didn't have too much success. However it is quite possible to export the processing sketch to an object format say DXF if you don't need coordinates in realtime (my povwriter library does just that, it exports geometry to the PovRAY sdl). If you use toxiclibs there is support for regular STL export etc.

Konstanti..

Re: 3d tree-growth simulator

1 year ago

modelX(0,0,0), modelY(0,0,0), modelZ(0,0,0), seems to work for getting the previous coordinate system's pointZero(x,y,z) variables.

Do you think there could be a command for seting X - axis, Y - axis, Z - axis orientations at their previous settings (before pushMatrix)? Or else I would have to find a way to manually store their rotations and apply them again each time.

monkstone

Re: Re: 3d tree-growth simulator

1 year ago

I don't think there is an easy way, from memory the joons-render library by Joon Hyub Lee has a good way of storing axis rotations, and translations, he uses this for the sphere object, I had a mind to copy it for my povwriter library.

Konstanti..

Re: 3d tree-growth simulator

1 year ago

In the example below, I tried doing it without using any libraries.

The code seems to work quite well, but it just occured to me that there is a serious mistake in it. And that lies in the rotateLE, rotateUD and twistLR funcrions of the branch class. each of these classes is supposed to bring the coordinate system to a relative position to its previous, then rotate it to match its previous's rotation, and then apply a new rotation to it. But just applying a series of rotations again does not work, unless they come in the right order. Which means that (rotateY(PI/2); rotateZ(PI/4); rotateX(pi/8);) is not the same as (rotateZ(PI/4); rotateY(PI/2); rotateX(pi/8);)

Anyway, this is a problem I would like to solve.

The modelX Y Z function works quite well, though.

The example works fine for anyone who wants to play abit.

*Perhaps I should open a new thread about the axis problem...

/////////////////////////////
//REAL TIME GROWING TREE
/////////////////////////////
import processing.opengl.*;
/////////////////////////////
//Global Settings
float camx = 800, camy = 800, camz = 800, //set camera
tarx = 0, tary = 0, tarz = 400,
upx = 0, upy = 0, upz = -1;
float energyStart = 10; //0.4 to 10 preferably
float time = 0;
/////////////////////////////
Branch tree;
void setup() {
size(1000, 700, P3D);
stroke(255, 50);
//setup tree
PVector pStart = new PVector(0, 0, 0);
tree = new Branch(energyStart, 1, 1, pStart, 0.0, -PI/2, 0.0);
tree.update();
}
void draw() {
time+=0.01;
background(0);
camx = sin(time)*800;
camy = cos(time)*800;
camera(camx, camy, camz, tarx, tary, tarz, upx, upy, upz);
tree.update();
tree.display();
}
class Branch {
float spltLength = 25;
int numChildren = 5;
float maxAngle = PI/8;
int maxGen = 7;
float energy;
int gen;
//////////////////////
PVector pStart; //start point
float rotationX;
float rotationY;
float rotationZ;
float distance;
//calculated variables
PVector pEnd; //end point
////////////////////////////
int axis; // 1 = Xaxis, 2 = Yaxis, 3 = Zaxis
float ang;
Branch[] children;
Branch( float energy, int gen, float distance, PVector pStart,
float rotationX, float rotationY, float rotationZ) {
this.energy = energy;
this.gen = gen;
this.distance = distance;
this.pStart = pStart; this.distance = distance;
this.rotationX = rotationX;
this.rotationY = rotationY;
this.rotationZ = rotationZ;
}
void update() {
growBranch();
// if splitLength is reached, create children and update them
if ((distance >= spltLength)&&(gen<maxGen)) {
// create child-branches if they don't exist
if (children == null) createChildren();
for (int i =0; i<children.length; i++) {
children[i].pStart = pEnd;
children[i].update();
}
}
}
void createChildren() {
children = new Branch[numChildren];
for (int i = 0; i<numChildren; i++) {
if (i == 0) {
children[i] = new Branch(energy/1.1, gen+1, 1, pEnd, rotationX, rotationY, rotationZ);
children[i].update();
}
else{
children[i] = new Branch(energy/1.4, gen+1, 1, pEnd, rotationX, rotationY, rotationZ);
children[i].twistLR(random(-maxAngle,maxAngle));
children[i].rotateLR(random(-maxAngle,maxAngle));
children[i].rotateUD(random(-maxAngle,maxAngle));
children[i].update();
}
}
}
void rotateUD(float ang){ //around Y axis
//set the coordinate system to match parent coordinate system
pushMatrix();
translate(pStart.x,pStart.y,pStart.z); // go to start point
rotateX(rotationX);
rotateY(rotationY);
rotateZ(rotationZ);
rotateY(ang); rotationY += ang;
translate(distance,0,0); //go to endpoint
pEnd = new PVector(modelX(0,0,0),modelY(0,0,0),modelZ(0,0,0));//get world coordinates for endpoint
popMatrix();
}
void rotateLR(float ang){ //around Z axis
this.ang = ang;
//set the coordinate system to match parent coordinate system
pushMatrix();
translate(pStart.x,pStart.y,pStart.z); // go to start point
rotateX(rotationX);
rotateY(rotationY);
rotateZ(rotationZ);
rotateZ(ang); rotationZ += ang;
translate(distance,0,0); //go to endpoint
pEnd = new PVector(modelX(0,0,0),modelY(0,0,0),modelZ(0,0,0));//get world coordinates for endpoint
popMatrix();
}
void twistLR(float ang){ //around X axis
//set the coordinate system to match parent coordinate system
pushMatrix();
translate(pStart.x,pStart.y,pStart.z); // go to start point
rotateX(rotationX);
rotateY(rotationY);
rotateZ(rotationZ);
translate(distance,0,0); //go to endpoint
rotateX(ang); rotationX += ang; //alter coordinate system
pEnd = new PVector(modelX(0,0,0),modelY(0,0,0),modelZ(0,0,0));//get world coordinates for endpoint
popMatrix();
}
void growBranch(){
float factor = 1 + energy/(1.5*sq(distance));
distance *= factor;
pushMatrix();
translate(pStart.x,pStart.y,pStart.z); // go to start point
rotateX(rotationX);
rotateY(rotationY);
rotateZ(rotationZ);
translate(distance,0,0); //go to endpoint
pEnd = new PVector(modelX(0,0,0),modelY(0,0,0),modelZ(0,0,0));//get world coordinates for endpoint
popMatrix();
}
void display() {
strokeWeight(int(distance/10));
if (children == null) {
//point(end.x, end.y, end.z);
stroke(0,255,0,int(distance*4));
beginShape(LINES);
vertex(pStart.x, pStart.y, pStart.z);vertex(pEnd.x, pEnd.y, pEnd.z);
endShape();
}
else {
stroke(255,100,0,int(distance*2));
beginShape(LINES);
vertex(pStart.x, pStart.y, pStart.z);vertex(pEnd.x, pEnd.y, pEnd.z);
endShape();
for (int i = 0; i<children.length; i++) {
children[i].display();
}
}
}
}

Konstanti..

Re: 3d tree-growth simulator

1 year ago

I think there should be a list of transformations that stores the previous rotations. then each time the local coordinate system is redefined, the list is applied to it. Then the new rotation is applied to it and stored in the list. Perhaps there should also be a separate class for all that, as well.

Or, perhaps, we could use vectors... Trying to match one axis of the local coordinate system to a 3d vector (which is its previous rotation).

Both of the solutions seem to be complicated enough, though...

Well, back to business.

Konstanti..

Re: 3d tree-growth simulator

1 year ago

By the way I just tried to run the script on processing 1.5.1

and it does not work at all...

Don't know why.

If you want to test it use 2.0

Konstanti..

Re: 3d tree-growth simulator

1 year ago

Well, it's been a few days since the last post on the matter.

In the meanwhile i have been silently working on this, this time taking it from the very beginning.

the code below is a very simple 2d example of an interactive tree.

Nothing special, but i made a funny small application and wanted to share.

It is very simple and i think it will run trouble-free on any version of processing.

Here is the sketch on the openProcessing page, incase someone just wants to take a look.

And here is another version.

void setup() {
size(800, 600, P2D);
}
int maxbranch =8;
float ang = 0;
float ang2 = 0;
float distance;
PFont font = createFont("Arial", 20);
void draw() {
background(80);
//stroke(0);
ang2 = map(mouseX, 0, width, 0, 2*PI);
ang = map(mouseY, 0, 600, -PI, 0);
distance = 160;
pushMatrix();
translate(400,550);
branch(0);
popMatrix();
infoText();
}
void branch(float incnt){
float cnt = incnt;
cnt++;
stroke(0,255/(cnt/2));
fill(255,255,0,255/(cnt/2));
quad(-15/cnt,0,15/cnt,0,15/(cnt+1),-distance/(cnt),-15/(cnt+1),-distance/(cnt));
ellipseMode(CENTER);
if (cnt>1) ellipse(0,0,30/cnt,30/cnt);
if (cnt < maxbranch){
pushMatrix();
translate(0,-distance/(cnt));
rotate(ang+ang2);
branch(cnt);
popMatrix();
pushMatrix();
translate(0,-distance/(cnt));
rotate(-ang+ang2);
branch(cnt);
popMatrix();
}
}
void infoText(){
stroke(0);
fill(0);
String txt = "PLAY THE TREE \n" +
"Move mouse around and see what happens \n" +
"LMB = increase branches \n" + "RMB = decrease branches \n" +
"Number of branches = " + (maxbranch);
text(txt,20,40);
}
void mouseReleased(){
if (mouseButton == LEFT){
if (maxbranch < 12) maxbranch++;
}
if (mouseButton == RIGHT){
if (maxbranch > 1) maxbranch--;
}
}

Replies(26)

Re: 3d tree-growth simulator

Re: Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: Re: 3d tree-growth simulator

The Algorithmic Beauty of Plants

Re: 3d tree-growth simulator

Re: Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Re: 3d tree-growth simulator

Statistics

Tags

Actions

Related Posts