Here's something to get you started. This sketch creates 100 random vectors with an x, y and z each ranging from 0 to dim, which I have set to 250. I moved everything to the center of the screen and then flipped the Y (which makes more sense in math, in Processing upwards Y is down). There is some rotation going on. There is a bounding box. Finally the main attraction are the 3D scattered points, which also move up and down in the Y direction. They are displayed with a point and a transparent-ish line going from zero to the point's y. As you can see it's pretty basic.

Hope this helps!

1. import processing.opengl.*;
2.  
3. PVector[] vecs = new PVector[100];
4. int dim = 250;
5.  
6. void setup() {
7.   size(500,500,OPENGL);
8.   for (int i=0; i<vecs.length; i++) {
9.     vecs[i] = new PVector(random(dim),random(dim),random(dim));
10.   }
11. }
12.  
13. void draw() {
14.   background(0);
15.   translate(width/2,height/2);
16.   scale(1,-1,1); // so Y is up, which makes more sense in plotting
17.   rotateY(radians(frameCount));
18.  
19.   noFill();
20.   strokeWeight(1);
21.   box(dim);
22.  
23.   translate(-dim/2,-dim/2,-dim/2);
24.   for (int i=0; i<vecs.length; i++) {
25.     vecs[i].y = noise(frameCount * 0.005 + i) * dim;
26.     PVector v = vecs[i];
27.     stroke(255,75);
28.     strokeWeight(2);
29.     line(v.x,0,v.z,v.x,v.y,v.z);
30.     stroke(255);
31.     strokeWeight(5);
32.     point(v.x,v.y,v.z);
33.   }
34. }

Hi Amnon,

you made a great example :), but I would like to use it in netbeans, so that I can change this http://youtu.be/MqMHmBnos7k into "3d".
Unfortunately I couldn't figure out how to import the opengl lib, because I don't know excatly which opengl processing uses and where it has to be.

Have you don this and could tell me, how to do that?

Best regards, Andreas

You have to import the opengl jars.

See this: http://programminginteractivity.com/wordpress/?p=175