3D rotation (logic?) problem

General Discussion Other

polar2

in General Discussion • Other • 1 year ago

Hello everybody,

I'm doing a software for mental rotations training. It shows you some 3d object, then prompts you to rotate it in your mind along each axis (three numbers are shown). Then it shows you 3 possibilities of the result, and you should choose the correct one.

My frustrating problem is, that "rotateX" functions rotates objects "around their relative position to the origin". Which means, that when I rotate object around one axis, the directions of other two changes! So the following rotation, say around Y, is not done along the original Y axis, but some new vector. I need to be able to rotate it absolutely, with reference to absolute coordinate system (like when you are standing in a room, and object is in corner, and then rotates along each corners' axis, one after another, always from your, stable, point of view).

Is it possible to implement this request in processing (maybe even counterintuitively, through some camera-view implementaion)? I definitely hope for that, and thank you for any comments.

----

EDIT 1: After some theoretical and practical research :), I think I can rephrase my question:

How can I do rotation in all three directions at once?

Something like rotate(x_degrees, y_degrees, z_degrees) ?

-----

EDIT 2

I solved it (scroll down)

Replies(7)

monkstone

Re: 3D rotation (logic?) problem

1 year ago

Take a look a proscene or ocd libraries I think they support what you want to do.

rbrauer

Re: 3D rotation (logic?) problem

1 year ago

I've used the Apache Commons Math library for 3D rotations and thought it might be helpful. http://commons.apache.org/math/userguide/geometry.html

Chrisir

Re: 3D rotation (logic?) problem

1 year ago

Am I stating the obvious here when I point out that processing can

rotate a box around itself anywhere on the screen,
around the y-axis in a distance and
like a planet around a sun in the middle of the screen?

I show all three ways:

// The  sketch in 3D shows different ways of 
// 3D box rotation (degree measurement).

float myAngle=-90; // degree measurement

void setup () {
  // Init
  // 3D requires P3D or OPENGL as a parameter to size()
  size (600, 600, P3D);
}

void draw () {
  // repeated continously
  background(22);
  // switch on lights  
  lights();
  // color for lines
  stroke(111);
  // 
  // Box: A box with equal dimension on all sides is a cube.
  // red: in a distance around Y-axis
  pushMatrix();
  rotateY(radians(myAngle));
  translate(158, 148, -10); 
  fill (color(242, 2, 2));  // red
  box(40); // only one parameter: box(size);
  popMatrix();
  // 
  // Box: A box with equal dimension on all sides is a cube.
  // green: around itself 
  pushMatrix();
  translate(258, 448, -10); 
  rotateY(radians(myAngle));
  fill (color(2, 222, 2)); // green
  box(40); // only one parameter: box(size);
  popMatrix();
  //
  // Box: A box with equal dimension on all sides is a cube.
  // blue: around the green box
  translate(258, 0, 0); 
  pushMatrix();
  rotateY(radians(myAngle));
  translate(158, 448, -10); 
  fill (color(2, 2, 222)); // blue
  box(40); // only one parameter: box(size);
  popMatrix();
  // 
  myAngle+=3; // speed
  if (myAngle>=360) {
    myAngle=0; // keep in degree
  }
  //
}

Greetings, Chrisir always willing to state the obvious...

Chrisir

Re: 3D rotation (logic?) problem

1 year ago

maybe you just need

// green: around itself
pushMatrix();
translate(258, 448, -10);
// rotateY(radians(myAngle));
rotateX(radians(50)); // three rotations here
rotateY(radians(45));
rotateZ(radians(10));
fill (color(2, 222, 2)); // green
box(40); // only one parameter: box(size);
popMatrix();

polar2

Re: 3D rotation (logic?) problem

1 year ago

Chrisir thanks a lot for your ideas - I just think my problem is, that this multiple axis rotation (which I already use) gives "wrong" results. Let me explain. In following code, a create a tall box (note that tallest dimension = Y axis). After first rotation (90 degrees X), it "lies on the ground", which is ok (not visible in example). But when doing its second rotation (45 degrees Y), it rotates along its Y axis (the tallest dimension, its former Y), rather then along the original, (space-tied) Y axis.

int valueX = 0, valueY = 0;

void setup () {
// Init
// 3D requires P3D or OPENGL as a parameter to size()
size (600, 600, P3D);
}
void draw () {
background(22);
lights();
stroke(111);

line(100,500,-200,800,500,-200); // x
line(100,500,-200,100,0,-200); // y
line(100,500,-200,100,500,200);

pushMatrix();
translate(258, 448, -10);
rotateX(radians(valueX));
rotateY(radians(valueY));
box(30, 200, 30);
popMatrix();
}

void mouseClicked() {
if(valueX == 0) {
valueX = 90;
valueY = 45;
} else {
valueX = 0;
valueY = 0;
}
}

hellochar

Re: 3D rotation (logic?) problem

1 year ago

Unfortunately, this isn't as straightforward as you might think. You'll have to convert the "world x-axis" into coordinates represented by the current coordinate system. Basically, we have to fake "rotating all 3 at the same time" by rotating one at a time along the right vector. Let me know if you need more help.

polar2

solved! :)

1 year ago

To solve it (to multi-rotate object along with the firm, world's axis, not changeable object axis), I used applyMatrix() function with general rotational matrix content (described e.g. here , paragraph 3).

int valueX = 90, valueY = 45, valueZ = 0;

void setup () {
size (600, 600, P3D);
}
void draw () {
background(22);
lights();

stroke(111);
line(100,500,-200,800,500,-200); // x
line(100,500,-200,100,0,-200); // y
line(100,500,-200,100,500,200); // z

translate(250, 400, -10);

// white basic box
fill(255, 255, 255);
box(30, 200, 30);

// red box rotated one axis at a time (axis "stick" to the object itself)
pushMatrix();
fill(255, 0, 0);
rotateX(radians(valueX));
rotateY(radians(valueY));
rotateZ(radians(valueZ));
box(30, 200, 30);
popMatrix();

// green box rotated three axis at once (axis "stick" to the world/"ground")
fill(0, 255, 0);
rotateXYZ(radians(valueX), radians(valueY), radians(valueZ));
box(30, 200, 30);
}

// BFG function
void rotateXYZ(float xx, float yy, float zz) {
float cx, cy, cz, sx, sy, sz;

cx = cos(xx);
cy = cos(yy);
cz = cos(zz);
sx = sin(xx);
sy = sin(yy);
sz = sin(zz);

applyMatrix(cy*cz, (cz*sx*sy)-(cx*sz), (cx*cz*sy)+(sx*sz), 0.0,
cy*sz, (cx*cz)+(sx*sy*sz), (-cz*sx)+(cx*sy*sz), 0.0,
-sy, cy*sx, cx*cy, 0.0,
0.0, 0.0, 0.0, 1.0);
}

Top Reply