3D point represented with pixels[]

Programming Questions

asimes

3D point represented with pixels[]

in Programming Questions • 1 year ago

I think my last post was too long, I deleted it. Here is a much simpler question:

I have a sketch that has a lot of 3D points in a box. I had been using spheres to represent the points but this is very, very slow. I would like to find a different method of visualizing and I thought that I could speed up the sketch a lot if I could represent the points somehow with pixels[]. How can I go about doing this?

Replies(12)

tfguy44

Re: 3D point represented with pixels[]

1 year ago

Spheres are hard to draw - they're composed of many different triangles - so drawing one is actually a lot of effort.

Instead, why don't you try representing a point with a point?

The function point(x,y,z) will draw a point in 3D space that's the color set by stroke().

amnon.owed

Re: 3D point represented with pixels[]

1 year ago

Since pixels[] is 2D and your points are 3D you need to find the 2D position on the screen of your 3D point. You can do this using screenX and screenY. You can then display all unique screen xy-positions using pixels[]. I doubt however if all of that is a good solution, it seems a bit convoluted.

Some other suggestions:

You could use sphereDetail() to lower the detail of the sphere, for example to 3.

You could use point() instead of translate+sphere.

Use a GLGraphics GLModel to display the points.

Chrisir

Re: 3D point represented with pixels[]

1 year ago

Couldn't you save it in some 3d-format or mesh and export to POVRay or so?

That would be much slower but could look great.

There are also other ways to optimize your code such as get rid of sqrt, use look-up tables for sin, cos etc.

Greetings, Chrisir

asimes

Re: 3D point represented with pixels[]

1 year ago

I didn't know about sphereDetail(), that helps the speed a lot but it still doesn't look great represented as spheres. I'll have to try the screenX / screenY method at some point. I found a tutorial on Ray Marching, maybe I can use it with that.

I can't seem to get anything that doesn't look like an ugly black blob with points. Even if I set a stroke() color before calling the points it doesn't change. I don't really understand why, I'll post the code below (the original sphere rendering code). Almost all of the code can be ignored, the part that does the rendering is this:

if (n > 1) {
translate(i-screenSize/2, j-screenSize/2, k-screenSize/2);
float logC = log(float(n))/log(float(maxIterations+1));
fill(logC*255);
sphere(1);
translate(-i+screenSize/2, -j+screenSize/2, -k+screenSize/2);
}

Chrisir I may try that in the future when I have something worth making a high quality image of but for the time being I need fast renders to see what I'm doing. Eventually I would like to make something like that though.

Here is the code (again, note that this is the slow sphere version):

float xmin = -2;
float ymin = -2;
float zmin = -2;
float wh = 4;
int maxIterations = 10;
int power = 2;
int screenSize = 100;
void setup() {
size(screenSize, screenSize, P3D);
noStroke();
noLoop();
}
void draw() {
background(255);
translate(width/2, height/2);
directionalLight(255, 255, 255, 1, 1, -1);
directionalLight(255, 192, 192, 0, 1, -1);
float xmax = xmin+wh;
float ymax = ymin+wh;
float zmax = zmin+wh;
float dx = (xmax-xmin)/screenSize;
float dy = (ymax-ymin)/screenSize;
float dz = (zmax-zmin)/screenSize;
int count = 0;
float x = xmin;
for (int i = 0; i < screenSize; i++) {
float y = ymin;
for (int j = 0; j < screenSize; j++) {
float z = zmin;
for (int k = 0; k < screenSize; k++) {
float rad = sqrt(x*x+y*y+z*z);
float phi = atan2(z, x);
float phiLength = sqrt(x*x+z*z);
float theta = atan2(phiLength, y);
float addx = cos(phi)*sin(theta)*rad;
float addy = cos(theta)*rad;
float addz = sin(phi)*sin(theta)*rad;
float nx = x;
float ny = y;
float nz = z;
int n = 0;
while (n < maxIterations) {
float nRad = pow(sqrt(nx*nx+ny*ny+nz*nz), power);
float nPhi = atan2(nz, nx)*power;
float nPhiLength = sqrt(nx*nx+nz*nz);
float nTheta = atan2(nPhiLength, ny)*power;
nx = cos(nPhi)*sin(nTheta)*nRad+addx;
ny = cos(nTheta)*nRad+addy;
nz = sin(nPhi)*sin(nTheta)*nRad+addz;
if (nx*nx+ny*ny+nz*nz > 4) break;
n++;
}
if (n > 1) {
translate(i-screenSize/2, j-screenSize/2, k-screenSize/2);
float logC = log(float(n))/log(float(maxIterations+1));
fill(logC*255);
sphere(1);
translate(-i+screenSize/2, -j+screenSize/2, -k+screenSize/2);
}
z += dz;
}
y += dy;
}
x += dx;
println((float(count)/screenSize)+"%");
count++;
}
println("Time: "+millis());
}

hellochar

Re: 3D point represented with pixels[]

1 year ago

The thing with 3D is that shapes get most of their realism from lighting. You might consider replacing sphere(1) with a call to box(1), and then learning a bit about lighting in Processing.

We also get an understanding of a 3D shape by looking at how it changes in space over time; with 3D scenes it's easiest to do this by adding a rotateX/Y/Z that depends on the current time at the top of draw(). Unfortunately, Mandelbulb is very computationally expensive, meaning you'll get <1 frame per second without optimizations - this is far too much time for our brains to recognize the shape being drawn.

You can get around this in a couple ways:

a) render each frame to an image on file and then stitch them together into a movie. This might be the most straightforward way, but it could take LOTS of time.

b) Do some optimization - for instance, if you can calculate the 3D point's position on your screen and see that another box has already been drawn "in front" of it, you don't have to iterate that point at all, since it'll be hidden behind the other box regardless.

asimes

Re: 3D point represented with pixels[]

1 year ago

The boxes are faster than spheres but they also look terrible (worse than spheres actually). I'm not planning on making live programmed animations, I just want to higher quality images. It seems like primitive geometry is not the way to go unless I make meshes on the fly or something and light those.

Unfortunately I need to wrap my head around doing the 3D to 2D conversion first, but I'm glad you wrote the "in front" part. I think I can imagine a way to determine which 3D point is closest given a 2D pixel, I'll just only draw the closest point for any given pixel then.

Unless I make this fantastically faster it probably will not reach 1 frame per second for a big screen. I'll try my best and post again when the render looks better.

asimes

Re: 3D point represented with pixels[]

1 year ago

Well, a bit of progress. I tried out a few of the methods mentioned and all of them have some visual artifacts but the pixels[] method seems to have the least. I think it can be improved, the main problem with it is that I have to convert screenX, screenY from a float to an int so I can use it to index pixels[]. Maybe building a mesh somehow would be best, I dunno. Here are results so far:

screenX, screenY to pixels[] method: http://i.imgur.com/PG1Eb.png

if (n > 1) {
int px = int(screenX(i, j, k));
int py = int(screenY(i, j, k));
float pointDist = sqrt(sq(i-screenSize/2)+sq(j-screenSize/2)+k*k);
if (pointDist < closestD[px+py*screenSize]) {
closestD[px+py*screenSize] = pointDist;
float distE = 0.5*sqrt(x*x+y*y+z*z);
pixels[px+py*screenSize] = color(distE*255);
}
}

NOTE: earlier in the code I also have:

float[] closestD = new float[screenSize*screenSize];
for (int i = 0; i < screenSize*screenSize; i++) closestD[i] = 214748347;

So far this one looks best.

point(x, y, z) with stroke() color method: http://i.imgur.com/047mr.png

if (n > 1) {
float distE = 0.5*sqrt(x*x+y*y+z*z);
stroke(distE*255);
point(i, j, k);
}

Embarrassingly enough I just forgot to multiply by 255 when I said I was getting black blobs before. This still has a lot of visual artifacts though.

sphere() with translate method: http://i.imgur.com/ild10.png

if (n > 1) {
translate(i-screenSize/2, j-screenSize/2, k-screenSize/2);
float distE = 0.5*sqrt(x*x+y*y+z*z);
fill(distE*255);
sphere(1);
translate(-i+screenSize/2, -j+screenSize/2, -k+screenSize/2);
}

NOTE: This is done with:

sphereDetail(3);
directionalLight(255, 255, 255, 1, 1, -1);
directionalLight(255, 255, 255, 0, 1, -1);

This doesn't look too great. If I make sphereDetail() bigger it looks a better but it is absurdly slow.

Chrisir

Re: 3D point represented with pixels[]

1 year ago

can't you just write the naked 3D coords in a csv-file and run it as spheres POVRay?

if you have a csv, I can have a look, when you send me a PM or so.

asimes

Re: 3D point represented with pixels[]

1 year ago

Can you explain what that means please? I don't know what you mean by run it as spheres POVRay, I also don't really know what POVRay is.

I think I know how to make a CSV, does the order that points are saved matter? Would I just save a text file with a .csv extension and comma separate the x, y, z values?

Chrisir

Re: 3D point represented with pixels[]

1 year ago

yeah csv with commas, x,y,z

Chrisir

Re: 3D point represented with pixels[]

1 year ago

povray is a ray tracing program a render

http://povray.org/

there are also some programs here that can do exports to POVRay.

asimes

Re: 3D point represented with pixels[]

1 year ago

Huge improvement after using round() instead of int() when converting floats to ints. Still a number of artifacts unfortunately. Code for rendering now is:

if (n == maxIterations) {
int px = round(screenX(i, j, k));
int py = round(screenY(i, j, k));
float pointDist = sqrt(sq(i-screenSize/2)+sq(j-screenSize/2)+k*k);
if (pointDist < closestD[px+py*screenSize]) {
closestD[px+py*screenSize] = pointDist;
float distE = 0.5*sqrt(x*x+y*y+z*z);
pixels[px+py*screenSize] = color(distE*255);
}
}

Still have this earlier in the code:

float[] closestD = new float[screenSize*screenSize];
for (int i = 0; i < screenSize*screenSize; i++) closestD[i] = 214748347;

Any suggestions to remove visual artifacts would be greatly appreciated

Top Reply