You can have three variables x, y, z that are used to keep track of the sphere's location. You can change these three values from the keyPressed method. For example through the up, down etc. keys.

Code Example

1. import processing.opengl.*;
2. int x, y, z;
3. int speed = 10;
4.  
5. void setup() {
6.   size(600, 600, OPENGL);
7. }
8.  
9. void draw() {
10.   background(123, 0, 5);
11.   lights();
12.   pushMatrix();
13.   translate(width/2,height/2);
14.   translate(x, y, z);
15.   sphere(100);
16.   popMatrix();
17. }
18.  
19. void keyPressed() {
20.   if (keyCode == UP) { y-=speed; }
21.   if (keyCode == DOWN) { y+=speed; }
22.   if (keyCode == LEFT) { x-=speed; }
23.   if (keyCode == RIGHT) { x+=speed; }
24.   if (keyCode == SHIFT) { z+=speed; }
25.   if (keyCode == CONTROL) { z-=speed; }
26. }

Of course this is possible.

Based on your code, I would say it will help you to look at the learning section and the examples that come with Processing to get some of the basics. Both are conveniently organised into different topics. With regard to multiple objects, spheres and boxes, see the example below. Press space to cycle through the objects and b to toggle between box/sphere. With regard to lines behind or other things around the object, it's easier to realise using object-oriented programming (which is also covered in the learning section).

Adapted Code (to move multiple objects)

1. import processing.opengl.*;
2. int numObject = 5;
3. PVector[] vecs = new PVector[numObject];
4. boolean[] boxSphere = new boolean[numObject];
5. int speed = 10;
6. int selected;
7.  
8. void setup() {
9.   size(600, 600, OPENGL);
10.   for (int i=0; i<vecs.length; i++) {
11.     vecs[i] = new PVector(random(-100, 100), random(-100, 100));
12.     boxSphere[i] = boolean(int(random(3)));
13.   }
14. }
15.  
16. void draw() {
17.   background(123, 0, 5);
18.   lights();
19.   translate(width/2, height/2);
20.   for (int i=0; i<vecs.length; i++) {
21.     pushMatrix();
22.     translate(vecs[i].x, vecs[i].y, vecs[i].z);
23.     if (i==selected) { fill(0, 255, 0); } else { fill(255); }
24.     if (boxSphere[i]) { box(50, 50, 50); } else { sphere(50); }
25.     popMatrix();
26.   }
27. }
28.  
29. void keyPressed() {
30.   // this keyPressed method is not very clean, but it's just to get the basic idea
31.   if (key == ' ') { selected++; if (selected >= vecs.length) { selected = 0; } }
32.   if (key == 'b') { boxSphere[selected] = !boxSphere[selected]; }
33.   PVector v = vecs[selected];
34.   if (keyCode == UP) { v.y-=speed; }
35.   if (keyCode == DOWN) { v.y+=speed; }
36.   if (keyCode == LEFT) { v.x-=speed; }
37.   if (keyCode == RIGHT) { v.x+=speed; }
38.   if (keyCode == SHIFT) { v.z+=speed; }
39.   if (keyCode == CONTROL) { v.z-=speed; }
40. }