3D math problem

Programming Questions

robbby

in Programming Questions • 3 years ago

my math visualization skills are shaky, I'm hoping someone can help me out.

the problem: I have have a 3D shape I've built on the x-y plane and I have a truncated cone whose axis is z. I want to wrap the 3D object around the cone.
I assume that I'll want to normalize the u-v of both the object and the cone. Then convert the object vertex and face coordinates to u-v-w vectors. Then, I'll want to copy those vertexes and faces in relation to the cone surface, allowing for the spread resulting from the curved surface and render them in world coordinates. Is that about right?
Can someone help me with the math? Especially allowing for the spread due to the curve.

Replies(5)

Jack Kern

Re: 3D math problem

3 years ago

This is what I'm picturing from what you've explained, but I don't think I'm totally clear on what you want the output to look like... Can you elaborate a bit more?

http://www.jackkern.com
http://www.twitter.com/ElectricJack

robbby

Re: 3D math problem

3 years ago

In Blender it's called shrink wrap, in Rhino it's flow to surface. It's basically wrapping a 3D object to a surface.
In the real world. Imagine having a model made of soft, pliable, stretchy material and then wrapping that model around a flower pot so that the model takes on the shape of the flower pot but remains the model in every other way.

Jack Kern

Re: 3D math problem

3 years ago

Ah ok, that makes a lot more sense then. Here's a quick example showing how to map a generated circle onto a dynamic truncated cone shape:

PVector surfacePoint = new PVector();
void setup()
{
size(400,400,P3D);
smooth();
}
void draw()
{
background(255);
noFill();
stroke(0);
strokeWeight(2);
translate( width/2, height/2, 10 );
rotateX( radians(60) );
// Calculate the radius of the circle we want to transform into cone coords
float r = map( sin(frameCount / 30.0), -1, 1, 0.8, 0.99 );
beginShape();
// This circle will have 100 verts to make it wrap nicely
for( int i=0; i<100; ++i )
{
// Now we map i from 0 to 2 PI so each vertex is evenly divided
// into the circle
float a = map( i, 0, 100, 0, 2*PI );
// Here's where we calculate the circle's coordinates as UV coords for
// the cone's surface; cos*r and sin*r will return values between -1 and
// 1 and we need them between 0 and 1
// (This could also be done by adding one and dividing by two but I
// think this is cleaner to read.)
//
// To pull points out of a generated model on the X/Y plane, just take
// the min/max of all the points, you can use the map commands providing
// your calculated min and max as the second and third parameters to
// calculate them as u/v coords. (Keep the last two params as 0 to 1)
float u = map( cos(a)*r, -1,1, 0, 1 );
float v = map( sin(a)*r, -1,1, 0, 1 );
// Finally we transform the u/v coords into our representation of the
// cone which requires a bottom radius, top radius (mouseX for
// interactivity), height, and output vector to store the results into.
// Further transformations are up to you!
wrapToConeSurface( u, v, 100, mouseX, 100, surfacePoint );
// Let's output our point.
vertex( surfacePoint.x, surfacePoint.y, surfacePoint.z );
}
endShape(CLOSE);
}
void wrapToConeSurface( float u, float v
, float r1, float r2, float height, PVector out )
{
float angle = 2*PI*u; // Here we map 0 - 1 to 0 - 2PI
float rad = lerp( r1, r2, v ); // This interpolates between the two radii
// Here u (converted to an angle) sets the x/y coords as a circle times
// the calculated radius (dependent on v).
out.x = cos( angle ) * rad;
out.y = sin( angle ) * rad;
// Here the height is set directly by v * height.
out.z = height * v;
}

Hope that helps!

http://www.jackkern.com
http://www.twitter.com/ElectricJack

Jack Kern

Re: 3D math problem

3 years ago

Also, if you need the w component, you'll just multiply that by the cone's surface normal at (u,v) and add it to the output point.

http://www.jackkern.com
http://www.twitter.com/ElectricJack

robbby

Re: 3D math problem

3 years ago

Thank you very much. I appreciate time time you take to help.

Top Reply

3D math problem

Replies(5)

Re: 3D math problem

Re: 3D math problem

Re: 3D math problem

Re: 3D math problem

Re: 3D math problem

Statistics

Tags

Actions

Related Posts