3D axis frame of reference manipulation (Anar)

werebear2..

3D axis frame of reference manipulation (Anar)

in Contributed Library Questions • 3 years ago

Hi everyone,

I'm working on a project using the anar library where we're transforming 3D objects (like translating, rotating, etc). We then need to shift the frame of reference of the 3D environment so that it's aligned with the object. For example: we draw a box and then shift it 30 units along the x axis and then rotate it 30 degrees. We need to then change the coordinate system so that it's shifted over and rotated exactly the same way the object is.

Is there any way to do this in anar? We'd appreciate the help.

Thanks!

Replies(11)

adamcsmit..

Re: 3D axis frame of reference manipulation (Anar)

3 years ago

I haven't used anar myself, so I don't know if this is exactly what you're after, but if you do:

translate(30, 0, 0);
rotateZ(30 * PI/180);

then all subsequent drawing commands will be shifted 30 units along the x-axis and then rotated 30 degrees about the z-axis. The PI/180 converts degrees to radians; you didn't specify which axis you wanted to rotate around, but you can use rotateX() or rotateY() as well.

Is that what you were after, or is there more to it?

werebear2..

Re: 3D axis frame of reference manipulation (Anar)

3 years ago

Sounds like what I'm looking for... If you then want that object to move 30 units along its "new" z-axis, would it do that or would it just move vertically (as in with respect to the original coordinate system orientation)?

Also, would those commands be in the same place and added to the same Transform object as the rotations to the box itself?

Thanks for your help!

werebear2..

Re: 3D axis frame of reference manipulation (Anar)

3 years ago

Hi again,

I just tried it and it doesn't shift the system like I need it to... for example, if I draw a box at the origin, move it 30 along the x axis, and then rotate it by 30 around the y axis, I need it to shift the coordinate system so that it's now xyz- aligned with the orientation of the box...so now the x and z axes are skewed in relation to the original coordinate system by 30 degrees around the y axis. This then will allow me to move the box along the new x-axis rather than along the default x-axis.

Does that make it any clearer or more confusing?

adamcsmit..

Re: 3D axis frame of reference manipulation (Anar)

3 years ago

Well, assuming you changed the rotateZ() call in the code above to a rotateY() it should still work. Possibly anar defines things differently than processing does?

Here's a little sketch I just wrote to show how processing does transformations. Red is the x-axis, green is y, and blue is z. The thick set of axes ( strokeWeight(5); ) is the base coordinate frame, and the thin set ( strokeWeight(1); ) is the coordinate system after the translation and rotation.

void setup() {
size(300, 300, P3D);
camera(-20, 70, 50, 0, 0, 0, 0, 0, -1);
smooth();
}
void draw() {
background(0);
strokeWeight(5);
drawAxes();
translate(30, 0, 0);
rotateY(30*PI/180);
strokeWeight(1);
drawAxes();
}
void drawAxes() {
stroke(255, 0, 0);
line(-50, 0, 0, 50, 0, 0);
stroke(0, 255, 0);
line(0, -50, 0, 0, 50, 0);
stroke(0, 0, 255);
line(0, 0, -50, 0, 0, 50);
}

gllllll

Re: 3D axis frame of reference manipulation (Anar)

3 years ago

In Anar, you could define a local reference frame using Transform(Pt,Pt,Pt); The three points given as parameters define a base plane. First point is X axis, 2th is the Origin of your local frame, 3rd is Y axis. The reference frame is also parametric, if the references points moves, the reference frame is modified. In this example, I pick three points from on an existing box.

Here is an example with a local references;

Group g = new Group();

void setup(){
      size(800,400,OPENGL);
      Anar.init(this);
      Anar.drawAxis();

      Param tr = new Param(30,0,100).addToSlidersMain();
      Param r1 = new Param(1,1,6).addToSlidersMain();
      Param r2 = new Param(0,0,6).addToSlidersMain();

      Obj box1 = new Box(10).rotateZ(r1).translateX(tr);
      g.add(box1);

      Obj box2 = new Box(10).fill(255,0,0);
      Transform t = new Transform(box1.face(0).pt(1),box1.face(0).pt(0),box1.face(0).pt(2));
      t.rotateX(r2);
      t.postTransform = false;
      box2.apply(t);

      g.add(box2);
}

void draw(){
      background(255);
      g.draw();
}

werebear2..

Re: 3D axis frame of reference manipulation (Anar)

3 years ago

Thanks so much for all your help!

I'm doing something similar to what gllllll mentioned, but am trying to get the orientation of an object and then setting the new coordinate system to that orientation, as follows

XYZ xyz = object .boundCenter(); //gets the center point of the object
float p = xyz.x();
float q= xyz.y();
float r= xyz.z();
Transform tempTform = new Transform(Anar.Pt(xyz),Anar.Pt(xyz),Anar.Pt(xyz));
//supposed to have changed the reference point of the coordinate system here
//but only does so for the point of the origin, not the orientation of the axes
tempTform.rotateX(radians(float(cmd[1])));
rotateX(radians(float(cmd[1])));
transforms.add(tempTform);
object.apply(tempTform);

Are XYZ points the only way of doing this or can you recommend a better way of getting the orientation and position of an object and then applying it to the coordinate system? The Anar javadoc isn't exactly complete in this area....

Thanks so much!

gllllll

Re: 3D axis frame of reference manipulation (Anar)

3 years ago

XYZ is only an interface. It's not a reference frame.To get the center of a shape, you may use PtCenter. PtCenter use a list of points. To use it with an Obj you may either construct a list:

Pts tmp = new Pts();
ArrayList lst = object.allPts();
for(int i=0; i<lst.size(); i++)
tmp.add((Pt)lst.get(i));

//...
Pt c = new PtCenter(tmp);

or add this constructor to PtCenter (you may use it as any points):

class PtCenterExt extends PtCenter{
PtCenterExt(Obj obj) {
            ArrayList lst = obj.allPts();
            for(int i=0; i<lst.size(); i++)
                  addParent((Pt)lst.get(i));
      }
}

//...
Pt c = new PtCenterExt(object);

Where c is the center of your object.

When you write:

Transform tempTform = new Transform(Anar.Pt(xyz),Anar.Pt(xyz),Anar.Pt(xyz));

With Anar.Pt(xyz), you create three instances of points with the same coordinates (the same point). You need to specify a reference frame with 3 different points (otherwise, rotations won't be right):

Pt ao = Anar.Pt(xyz); //origin
Pt ax = ao.copy().translateX(1); //x axis
Pt ay = ao.copy().translateY(1); //y axis
Transform tempTform = new Transform(ax,ao,ay);

But in this case the reference frame is not oriented with the object (this is maybe what you are looking for). If you want to create a reference frame based on the object, you may use points on your object like in the example of the previous post:

Transform t = new Transform(box1.face(0).pt(1),box1.face(0).pt(0),box1.face(0).pt(2));

You could then move to the center if this is what you are looking for

t.translate(center.minus(ao));
t.rotateZ(...);

werebear2..

Re: 3D axis frame of reference manipulation (Anar)

3 years ago

Thanks! That helps a lot...but I think might only work for boxes. I also have spheres and other shapes being drawn and still need to be able to orient the reference frame with this object, so doing the points on the object like how you did with the boxes might not work... is there a way to do the same thing as what you did here

Transform t = new Transform(box1.face(0).pt(1),box1.face(0).pt(0),box1.face(0).pt(2));

but with any object (so that it's not box-specific)?

Thanks!

gllllll

Re: 3D axis frame of reference manipulation (Anar)

3 years ago

You may want to create a reference frame that you move with the object, but you don't display it.

Group g = new Group();

void setup() {
      size(800, 400, OPENGL);
      Anar.init(this);
      Anar.drawAxis();

      Param tr = new Param(30, 0, 100).addToSlidersMain();
      Param r1 = new Param(0, 0, 6).addToSlidersMain();
      Param r2 = new Param(0, 0, 6).addToSlidersMain();

      Transform t1 = new Transform().rotateZ(r1).translateX(tr);

      Pt ao = Anar.Pt(0, 0, 0); // origin
      Pt ax = ao.copy().translateX(1); // x axis
      Pt ay = ao.copy().translateY(1); // y axis

      Pts refFrame = new Pts(ax, ao, ay).apply(t1);
      g.add(new Sphere(10).apply(t1));

      Obj box2 = new Box(10).fill(255, 0, 0);
      Transform tempTform = new Transform(refFrame.pt(0), refFrame.pt(1),refFrame.pt(2));
      tempTform.rotateX(r2);
      tempTform.postTransform = false;
      box2.apply(tempTform);

      g.add(box2);
}

void draw() {
      background(255);
      g.draw();
}

werebear2..

Re: 3D axis frame of reference manipulation (Anar)

3 years ago

Is there a simpler way of getting the orientation of an object, say if you were to draw a 3D arrow and then rotate and translate it, and apply that orientation as a new reference frame for the axes?

gllllll

Re: 3D axis frame of reference manipulation (Anar)

3 years ago

There's a page that explain the frame of references: Frame of Reference

For your arrow example, basically, this is similar to what is done in the example. The reference is only 3 points. You could move those three points in space and then use it as reference. You could replace the sphere with a 3D arrow and extract three points out of it.

You may also embed the three points inside an object, the frame will move with the object.

import anar.*;
import processing.opengl.*;

Group g = new Group();

void setup() {
      size(800, 400, OPENGL);
      Anar.init(this);
      Anar.drawAxis();

      Param tr = new Param(30, 0, 100).addToSlidersMain();
      Param r1 = new Param(0, 0, 6).addToSlidersMain();
      Param r2 = new Param(0, 0, 6).addToSlidersMain();

      //Create a default reference frame
      Pt ao = Anar.Pt(0, 0, 0); // origin
      Pt ax = ao.copy().translateX(1); // x axis
      Pt ay = ao.copy().translateY(1); // y axis

      //Create a sphere and add a reference frame
      Obj sphere = new Sphere(10);
      sphere.add(ax).add(ao).add(ay); //Add the reference frame
      sphere.rotateZ(r1).translateX(tr); //Transform the object
      g.add(sphere); //Add to main layer

      Obj box2 = new Box(10).fill(255, 0, 0);
      Transform tempTform = new Transform(sphere.pt(1),sphere.pt(0),sphere.pt(2)); //Extract the reference frame from the object
      tempTform.rotateX(r2); //Perform some transformations locally
      tempTform.postTransform = false;
      box2.apply(tempTform);

      //Transform the object afterwards
      sphere.rotateX(new Param(0, 0, 6).addToSlidersMain());

      g.add(box2);
}

void draw() {
      background(255);
      g.draw();
}

Top Reply