3D Arrow

General Discussion Other

hammergua..

in General Discussion • Other • 1 year ago

Can someone (help me) create a 3D arrow using beginShape()?

Replies(7)

hammergua..

Re: 3D Arrow

1 year ago

Like this but better, if there is a better way. I'm assuming there is...

float inc = 0;
void setup() {
size(600, 400, P3D);
noStroke();
}
void draw() {
background(0);
lights();
fill(255);
translate(width/2, height/2, 0);
rotateY(inc);
rotateX(inc);
inc += .01;
beginShape();
vertex(0, 0, 0);
vertex(50, -50, 0);
vertex(100, 0, 0);
endShape();
beginShape();
vertex(25, 0, 0);
vertex(25, 50, 0);
vertex(75, 50, 0);
vertex(75, 0, 0);
endShape();
beginShape();
vertex(0, 0, 50);
vertex(50, -50, 50);
vertex(100, 0, 50);
endShape();
beginShape();
vertex(25, 0, 50);
vertex(25, 50, 50);
vertex(75, 50, 50);
vertex(75, 0, 50);
endShape();
beginShape();
vertex(0, 0, 0);
vertex(0, 0, 50);
vertex(50, -50, 50);
vertex(50, -50, 0);
endShape();
beginShape();
vertex(50, -50, 0);
vertex(50, -50, 50);
vertex(100, 0, 50);
vertex(100, 0, 0);
endShape();
beginShape();
vertex(100, 0, 0);
vertex(100, 0, 50);
vertex(75, 0, 50);
vertex(75, 0, 0);
endShape();
beginShape();
vertex(75, 0, 0);
vertex(75, 0, 50);
vertex(75, 50, 50);
vertex(75, 50, 0);
endShape();
beginShape();
vertex(75, 50, 0);
vertex(75, 50, 50);
vertex(25, 50, 50);
vertex(25, 50, 0);
endShape();
beginShape();
vertex(25, 50, 0);
vertex(25, 50, 50);
vertex(25, 0, 50);
vertex(25, 0, 0);
endShape();
beginShape();
vertex(25, 0, 0);
vertex(25, 0, 50);
vertex(0, 0, 50);
vertex(0, 0, 0);
endShape();
}

cedrickie..

Re: 3D Arrow

1 year ago

what do you mean by "better". that already looks quite good. or do you mean "less code" ?

if thats the problem and you plan to use it more often you can create a arrow function and just call that.

if you dont want code like that add all, you can use one of the model loader library and load a 3d model of an arrow.

hammergua..

Re: 3D Arrow

1 year ago

Yeah I mean less code. I'm sure there must be a more efficient way to draw a simple arrow. I don't fully understand how this vertex stuff works

cedrickie..

Re: 3D Arrow

1 year ago

now that i look at it again, i see you are using a lot of begin and endshapes that you actually dont need. you could for example draw the arrow front in one go...

beginShape();

vertex(-50,50);

vertex(0, 0);

vertex(50, 50);

vertex(25,50);

vertex(25,100);

vertex(-25,100);

vertex(-25,50);

endShape(CLOSE);

but i think there is more room for optimization. lets see how far we get

hammergua..

Re: 3D Arrow

1 year ago

I got a better one. Anything else I can do?

float inc = 0;
void setup() {
size(600, 400, P3D);
noStroke();
}
void draw() {
background(0);
lights();
fill(255);
translate(width/2, height/2, 0);
rotateY(inc);
rotateX(inc);
inc += .01;
beginShape();
vertex(0, 0, 0);
vertex(50, -50, 0);
vertex(100, 0, 0);
vertex(75, 0, 0);
vertex(75, 50, 0);
vertex(25, 50, 0);
vertex(25, 0, 0);
endShape();
beginShape();
vertex(0, 0, 50);
vertex(50, -50, 50);
vertex(100, 0, 50);
vertex(75, 0, 50);
vertex(75, 50, 50);
vertex(25, 50, 50);
vertex(25, 0, 50);
endShape();
beginShape(QUAD_STRIP);
vertex(0, 0, 0);
vertex(0, 0, 50);
vertex(50, -50, 0);
vertex(50, -50, 50);
vertex(100, 0, 0);
vertex(100, 0, 50);
vertex(75, 0, 0);
vertex(75, 0, 50);
vertex(75, 50, 0);
vertex(75, 50, 50);
vertex(25, 50, 0);
vertex(25, 50, 50);
vertex(25, 0, 0);
vertex(25, 0, 50);
vertex(0, 0, 0);
vertex(0, 0, 50);
endShape();
}

cedrickie..

Re: 3D Arrow

1 year ago

float inc = 0;
void setup() {
size(600, 400, P3D);
noStroke();
}
void draw() {
background(0);
lights();
translate(width/2,height/2);
rotateY(inc);
rotateX(inc);
fill(255);
arrow();
inc += .01;
}
void arrow() {
int[] x = {-50, 0, 50, 25, 25, -25, -25, -50};
int[] y = {50, 0, 50, 50, 100, 100, 50, 50};
beginShape();
for (int i = 0;i<8;i++)vertex(x[i], y[i]);
endShape(CLOSE);
beginShape();
for (int i = 0;i<8;i++)vertex(x[i], y[i], 25);
endShape(CLOSE);
beginShape(QUAD_STRIP);
for (int i = 0;i<8;i++) {
vertex(x[i], y[i]);
vertex(x[i], y[i], 25);
}
endShape(CLOSE);
}

hammergua..

Re: 3D Arrow

1 year ago

Now that's efficient. Thanks!

3D Arrow

Replies(7)

Re: 3D Arrow

Re: 3D Arrow

Re: 3D Arrow

Re: 3D Arrow

Re: 3D Arrow

Re: 3D Arrow

Re: 3D Arrow

Statistics

Tags

Actions

Related Posts