[solved] 2D: find C from A and B rotating

Programming Questions

Chrisir

[solved] 2D: find C from A and B rotating

in Programming Questions • 5 months ago

Hello,

I got two points A and B.

A is fixed and B is rotating fully around A.

How can I find C if C is length h away from the center of A and B in 90 degrees?

See graphic 2 posts below.

Cheers!

Replies(8)

allonestr..

Re: 2D find C from A and B rotating

5 months ago

Would you like AB fixed and to find C relative to them, or are AB = AC = h fixed?

Edit - with diagram. I've renamed the distances AC and BC as e for edge as I want to use h for hypotenuse for the distance AB.

Without rotating the whole thing, the angle from A to B is 45° and the angle from A to C is 0° - a difference of 45°.

When you rotate the whole thing, the difference in the angles between the lines AB and AC is still 45°.

Pythagoras gives you the distances.

Is this enough for you to figure it out?

Chrisir

Re: 2D find C from A and B rotating

5 months ago

thanks a ton
I'll try

Chrisir

Re: 2D find C from A and B rotating

5 months ago

Sorry, I still don't get it.

When I have the length of the edge, like 125, how can I find C?

I can't say

Cx = Ax + e;
Cy = Ay + e;

Sorry....

amnon.owed

Re: 2D find C from A and B rotating

5 months ago

Indeed, the description could have been a bit clearer. I this what you mean?

Code Example

float br = 200;
float h = 50;
void setup() {
size(500, 500);
textAlign(CENTER, CENTER);
smooth();
}
void draw() {
background(255);
float ax = width/2;
float ay = height/2;
if (mousePressed) { br = dist(ax, ay, mouseX, mouseY); }
float bx = ax + sin(frameCount*0.01) * br;
float by = ay + cos(frameCount*0.01) * br;
float mx = lerp(ax, bx, 0.5);
float my = lerp(ay, by, 0.5);
float c1x = mx - cos(frameCount*0.01) * h;
float c1y = my + sin(frameCount*0.01) * h;
float c2x = mx + cos(frameCount*0.01) * h;
float c2y = my - sin(frameCount*0.01) * h;
noFill();
stroke(0);
line(ax, ay, bx, by);
line(mx, my, c1x, c1y);
line(mx, my, c2x, c2y);
ellipse(ax, ay, br*2, br*2);
ellipse(mx, my, h*2, h*2);
noStroke();
fill(255, 0, 0);
ellipse(ax, ay, 25, 25);
fill(0, 0, 255);
ellipse(bx, by, 25, 25);
fill(0, 255, 0);
ellipse(mx, my, 25, 25);
fill(0);
ellipse(c1x, c1y, 25, 25);
ellipse(c2x, c2y, 25, 25);
fill(255);
text("A", ax, ay);
text("B", bx, by);
text("M", mx, my);
text("C1", c1x, c1y);
text("C2", c2x, c2y);
}

Chrisir

Re: 2D find C from A and B rotating

5 months ago

Sorry, I need to do it with the mouse, mouse being Point B

C1 doesn't come out right as shown bold in lines 31 & 32

Thanks!

//
// https://forum.processing.org/topic/making-a-whole-shape-with-2-beziervertex-curves
/*
* Helper functions to visualize the vertices and control points of a Bézier curve.
* Replace vertex() by Vertex() and bezierVertex() by BezierVertex().
*/
float BezierHelper_prevX = 0;
float BezierHelper_prevY = 0;
void setup() {
//
size(900, 900);
//
noStroke();
smooth();
}
void draw() {
// fill(0, 12); // Make the shape blur onto the screen.
background(0); // Animate without blur
blob(mouseX, mouseY, 350, 350);
showAPosition(350, 350, "A");
float ax=350;
float ay=350;
float bx=mouseX;
float by=mouseY;
//
float mx = lerp(ax, bx, 0.5);
float my = lerp(ay, by, 0.5);
showAPosition(mx, my, "M");
//
float h = 40;
float c1x = mx - (bx / ax ) * h;
float c1y = my + (by / ay ) * h;
showAPosition(c1x, c1y, "C1");
}
void showAPosition( float a, float b, String myText) {
int size=4;
stroke(255);
noFill();
rect (a-size, b-size,
size*2, size*2);
text ( myText, a+6, b+5);
}
void blob(int p1X, int p1Y, int p2X, int p2Y) { // p1X = control point x axis ...
pushMatrix();
translate(0, 0); // move the position of the entire shape
// scale(size); // scale to size
beginShape(); // draw the blob
showAPosition (p1X, p1Y, "B");
endShape();
popMatrix();
}
//

quarks

Re: 2D find C from A and B rotating

5 months ago

If you use PVector(s) in a 2D space then it is easy

Assume that you have 2 PVector objects a and b and you want to find c

// 2D space so z=0 in all PVector objects

PVector a, b, c, n;

// Find mid point

c = PVector.add(b, a);

c.div(2);

// Find normal

n = PVector.sub(b,a);

n.normalize();

n.mult(h);

c.x += n.y;

c.y += -n.x;

// c now holds the position you want.

amnon.owed

Re: 2D find C from A and B rotating

5 months ago

Yeah, personally I also prefer to use PVector, because it usually shortens code and simplifies math problems.

But when you take Chrisir's above code and use trig, you can do it like this...

Adapted Code

void setup() {
size(900, 900);
noStroke();
smooth();
}
void draw() {
background(0);
float ax = 350;
float ay = 350;
showPosition(ax, ay, "A");
float bx = mouseX;
float by = mouseY;
showPosition(bx, by, "B");
float mx = lerp(ax, bx, 0.5);
float my = lerp(ay, by, 0.5);
showPosition(mx, my, "M");
float h = 40;
float a = atan2(bx-ax, by-ay);
if (a<0) a+=TWO_PI;
float c1x = mx - cos(a) * h;
float c1y = my + sin(a) * h;
showPosition(c1x, c1y, "C1");
float c2x = mx + cos(a) * h;
float c2y = my - sin(a) * h;
showPosition(c2x, c2y, "C2");
}
void showPosition(float a, float b, String myText) {
int size = 4;
noFill();
stroke(255);
rect(a-size, b-size, size*2, size*2);
text(myText, a+6, b+5);
}

Chrisir

Re: 2D find C from A and B rotating

5 months ago

Thank you all!

I used the code in another thread about curves:

https://forum.processing.org/topic/making-a-whole-shape-with-2-beziervertex-curves#25080000002092169

Thanks!

Top Reply