What does Vec2D.heading() in Toxiclibs do exactly?

in Contributed Library Questions • 2 years ago

/**
* This example demonstrates how to use the behavior handling
* (new since toxiclibs-0020 release) and specifically the attraction
* behavior to create forces around the current locations of particles
* in order to attract (or deflect) other particles nearby.
*
* Behaviors can be added and removed dynamically on both a
* global level (for the entire physics simulation) as well as for
* individual particles only.
*
* Usage: Click and drag mouse to attract particles
*/
/*
* Copyright (c) 2010 Karsten Schmidt
*
* This demo & library is free software; you can redistribute it and/or
* modify it under the terms of the GNU Lesser General Public
* License as published by the Free Software Foundation; either
* version 2.1 of the License, or (at your option) any later version.
*
* http://creativecommons.org/licenses/LGPL/2.1/
*
* This library is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
* Lesser General Public License for more details.
*
* You should have received a copy of the GNU Lesser General Public
* License along with this library; if not, write to the Free Software
* Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA
*/
import toxi.geom.*;
import toxi.physics2d.*;
import toxi.physics2d.behaviors.*;
int NUM_PARTICLES = 750;
VerletPhysics2D physics;
AttractionBehavior mouseAttractor;
Vec2D mousePos;
void setup() {
size(680, 382,P3D);
// setup physics with 10% drag
physics = new VerletPhysics2D();
physics.setDrag(0.05f);
physics.setWorldBounds(new Rect(0, 0, width, height));
// the NEW way to add gravity to the simulation, using behaviors
physics.addBehavior(new GravityBehavior(new Vec2D(0, 0.15f)));
}
void addParticle() {
VerletParticle2D p = new VerletParticle2D(Vec2D.randomVector().scale(5).addSelf(width / 2, 0));
physics.addParticle(p);
// add a negative attraction force field around the new particle
physics.addBehavior(new AttractionBehavior(p, 20, -1.2f, 0.01f));
}
void draw() {
background(255,0,0);
noStroke();
fill(255);
if (physics.particles.size() < NUM_PARTICLES) {
addParticle();
}
physics.update();
for (VerletParticle2D p : physics.particles) {
pushMatrix();
translate(p.x, p.y);
rotate(p.heading() + PI/2);
noStroke();
ellipse(0, 0, 5, 5);
stroke(0);
line(0,0,5,0);
popMatrix();
}
}
void mousePressed() {
mousePos = new Vec2D(mouseX, mouseY);
// create a new positive attraction force field around the mouse position (radius=250px)
mouseAttractor = new AttractionBehavior(mousePos, 250, 0.9f);
physics.addBehavior(mouseAttractor);
}
void mouseDragged() {
// update mouse attraction focal point
mousePos.set(mouseX, mouseY);
}
void mouseReleased() {
// remove the mouse attraction when button has been released
physics.removeBehavior(mouseAttractor);
}

This is for the most part just the Attraction2D demo, highlighted part I changed. The .heading() method isn't exactly what I was expecting (there is rotation, just not very much). Am I using it incorrectly?

—
http://jonobr1.com/

Replies(5)

toxmeister

Re: What does Vec2D.heading() in Toxiclibs do exactly?

2 years ago

You might want to change this into:

rotate(p.getVelocity().heading());

If you just use the particle's position, then heading() only gives you the angle relative to the coordinate system origin. What you want to show (I guess) is the direction of the particle's velocity vector...

Makes sense?

http://postspectacular.com | http://toxiclibs.org

jonobr1

Re: What does Vec2D.heading() in Toxiclibs do exactly?

2 years ago

Got it got it got it. Thanks toxi! I didn't notice the name of the variable, vel, in the ShiffmanFlocking demo — I thought it was just any ol' Vec2D.

—
http://jonobr1.com/

toxmeister

Re: What does Vec2D.heading() in Toxiclibs do exactly?

2 years ago

Also, as an aside: That whole pushMatrix/popMatrix block is hugely inefficient for what you're doing, when drawing the line you could just add the velocity to the particle position and save yourself all the pushing, translating and rotating:

for (VerletParticle2D p : physics.particles) {
noStroke();
ellipse(p.x, p.y, 5, 5);
stroke(0);
Vec2D vel=p.getVelocity().getNormalizedTo(5);
line(p.x,p.y,p.x+vel.x,p.y+vel.y);
}

http://postspectacular.com | http://toxiclibs.org

p3tr4s

Re: What does Vec2D.heading() in Toxiclibs do exactly?

4 months ago

Hi toxmeister,

I am working in a different script and your post was also very helpful, as I wanted to show directionality of moving objects.

I would like to ask how you know these commands:

Vec2D vel=p.getVelocity().getNormalizedTo(5);

Actually I don't really know how to read documentation of toxi....

Maybe, you can show me some data where is more such commands, to really learn the verletphysics and toxi?

I would be very pleased:)

toxmeister

Re: What does Vec2D.heading() in Toxiclibs do exactly?

4 months ago

Hi, being able to chain methods like this together is one of the core design features of toxiclibs and is used throughout the codebase and the various examples bundled with the releases. The point of it is to represent & group logically related operations as an easy-to-grasp unit or "sentence". You can also imagine it as a pipeline:

Vec2D vel=p.getVelocity().getNormalizedTo(5);

In goes a particle, we extract its velocity vector and then normalize the vector to a length of 5... This only works because each operation returns a value, which then acts as the input for the next.

Hth!

http://postspectacular.com | http://toxiclibs.org

Top Reply

Response title

Attachments

New to this Portal?