I haven't tried to do such thing, but I know there are lot of programs doing that, a number of them being written in Java. I am sure that a little search on the Internet can give lot of good results, more or less complex...

Well I'm not familiar with any other language than processing. We use it in school and in this one my knowledge is more or less pretty limited.

I've looked up several exampels that are written in Java but they dont really help me because I have no idea how to transform them into processing...

When you understand the processing language, it's not that hard to understand java, since it is actually the same language. A solution in processing could look exactly the same (maybe with changing 3-4 lines of code).
To use a java-class in processing, just copy that class into your sketch-directory with the ending ".java".

Here is a Sudoku-solver i found via google:
http://www.colloquial.com/games/sudoku/java_sudoku.html

When you save the source-code as "Sudoku.java" in your sketch-folder and reopen your sketch, there should appear a new tab with that name.

The following code should work to use the class from within processing:

1. void setup(){
     Sudoku solver= new Sudoku();
     String problem = "018 034 052 076 113 124 169 171 209 216 278 284 332 341 356 533 545 557 608 614 677 685 712 726 761 773 819 837 851 874";
     solver.main(split(problem, " "));
   }

Thanks for your effort but that doesnt really solve my problem. I was on this website too and tried to write the solving part in processing on my own but it didnt work. 


I managed to write like the whole thing around the sudoku solving part. But the actual solving part with putting the numbers in the empty cells, trying the next one till it doesnt work anymore and go back as far as to the point so  it has a real solution again wont even work at all..

Hmm. But there is really no big difference between java and processing.
I made some minor simplifications to the code from the website, so you can run it in processing:

1. void setup() {
     String theProblem = "018 034 052 076 113 124 169 171 209 216 278 284 332 341 356 533 545 557 608 614 677 685 712 726 761 773 819 837 851 874";
   
     int[][] matrix = parseProblem(split(theProblem, " "));
     writeMatrix(matrix);
     if (solve(0, 0, matrix))    // solves in place
       writeMatrix(matrix);
     else
       println("NONE");
   }
   
   boolean solve(int i, int j, int[][] cells) {
     if (i == 9) {
       i = 0;
       if (++j == 9)
         return true;
     }
     if (cells[i][j] != 0)  // skip filled cells
       return solve(i+1, j, cells);
   
     for (int val = 1; val <= 9; ++val) {
       if (legal(i, j, val, cells)) {
         cells[i][j] = val;
         if (solve(i+1, j, cells))
           return true;
       }
     }
     cells[i][j] = 0; // reset on backtrack
     return false;
   }
   
   boolean legal(int i, int j, int val, int[][] cells) {
     for (int k = 0; k < 9; ++k)  // row
       if (val == cells[k][j])
         return false;
   
     for (int k = 0; k < 9; ++k) // col
       if (val == cells[i][k])
         return false;
   
     int boxRowOffset = (i / 3)*3;
     int boxColOffset = (j / 3)*3;
     for (int k = 0; k < 3; ++k) // box
       for (int m = 0; m < 3; ++m)
         if (val == cells[boxRowOffset+k][boxColOffset+m])
           return false;
   
     return true; // no violations, so it's legal
   }
   
   int[][] parseProblem(String[] args) {
     int[][] problem = new int[9][9]; // default 0 vals
     for (int n = 0; n < args.length; ++n) {
       int i = int(args[n].substring(0, 1));
       int j = int(args[n].substring(1, 2));
       int val = int(args[n].substring(2, 3));
       problem[i][j] = val;
     }
     return problem;
   }
   
   void writeMatrix(int[][] solution) {
     for (int i = 0; i < 9; ++i) {
       if (i % 3 == 0)
         println(" -----------------------");
       for (int j = 0; j < 9; ++j) {
         if (j % 3 == 0) print("| ");
         if (solution[i][j] == 0) {
           print(" ");
         }
         else {
           print(solution[i][j]);
         }
         print(' ');
       }
       println("|");
     }
     println(" -----------------------");
   }

Wich parts are you having problems with?

Oh my God :O I'm speechless... You dont know how much you helped me right now :D

I think I just had too less knowledge of all the commands in processing. I wrote a much longer program with hundreds of if and else commands.. 

But no I have the problem that i dont really understand what the program does.
I kind of get what the solve part does, and definitely get how the "legal" part works. 
I'm almost embarrassed to say that but I dont understand how the boolean and return thing works..
Even if I try to understand the explanation on the processing Website i cant get it. (Maybe because my main language isnt English but I dont think so) 

Hey,
the "args"-array contains three-digit-strings, each one defining one spot in the sudoku-grid. For exampe "018" means the value in the first row and second column is "8". (The encoding is explained in the comments a the beginning of the source-code at the website linked above.)
 So the function "parseProblem()" just puts these values into a two-dimensional array, for "018" this would be:

1.     problem[0][1] = 8;