Seismograph

in Core Library Questions • 9 months ago

he folks, i am rather new to processing and I stuck with a problem. I try to visualize a motion detection with a line like a seismograph - so the line should grow over time. I tried a lot but it seems I am stumped. I post the most clear code with no experiments...
Any help is very appreciated.
ty B

import processing.video.*;
Timer timer;
PImage prevFrame;
Capture video;

int totalTime = 500;
int arrayLength = totalTime/int(frameRate);
float[] r1 = new float[arrayLength];
float threshold = 30;
int x = 0;

void setup() {
size(320, 240);
smooth();
background(0);
video = new Capture(this, width, height, 5);
prevFrame = createImage(video.width, video.height, RGB);
timer = new Timer(totalTime);
timer.start();
for (int i = 0; i < r1.length; i++) {
    r1[i]=0;
}
}

void draw() {

if (video.available()) {
    prevFrame.copy(video, 0, 0, video.width, video. height, 0, 0, video.width, video.height);
    prevFrame.updatePixels();
    video.read();
}

loadPixels();
video.loadPixels();
prevFrame.loadPixels();
//// motion detection
float totalMotion = 0;
for (int i = 0; i <video.pixels.length; i++) {
    color fgColor = video.pixels[i];
    color bgColor = prevFrame.pixels[i];
    float r1 = red(fgColor);
    float g1 = green(fgColor);
    float b1 = blue(fgColor);
    float r2 = red(bgColor);
    float g2 = green(bgColor);
    float b2 = blue(bgColor);

    float diff = dist(r1, g1, b1, r2, g2, b2);
    totalMotion += diff;
}

float avgMotion =totalMotion/video.pixels.length;

/// average motion over certain time
for (int i = 0; i < r1.length-1; i ++ ) {
    r1[i] = r1[i+1];
}
r1[r1.length-1]=avgMotion;
float sum = 0;
for (int i = 0; i < r1.length; i++) {
    sum +=r1[i];
}

float avgMinute = sum/(totalTime/100);

float r = avgMotion*2;

if (timer.isFinished()) {
    println(avgMinute);
    x+=5;
    stroke(255);
    noFill();
    strokeWeight(1);

    //// draw spline
    beginShape();
    curveVertex(x, avgMinute);
    endShape();
    timer.start();
}
}

Replies(4)

carstentr

Re: Seismograph

9 months ago

can I just say this:

scratch the back of my head

take a sip of wine (for christ's sake, it's weekend)

"I try to visualize a motion detection with a line like a seismograph - so the line should grow over time"

scratch my head again

I'm a seismologist. I don't recall that the lines grow.

Could you sort of pin out where the problem is?

sip of wine. Aah, it's weekend ;o)

bob_holzer

Re: Seismograph

9 months ago

ok forget the seismograph it is just the picture i have in my mind - i want to draw a line over time - the x coordinate is constantly increasing and the y coordinate is depending on the average amount i get from the motion detection - so every lets say 5 sec another point of the line is added.
I hope its clear now.. thx enjoy your wine

baud.r

Re: Seismograph

9 months ago

I think what I'd do is make an array of previous points and use that to draw the 'seismograph'. For example, create an array equal to the width of the image

At top:

float[] bufferValues;

In setup after size():

bufferValues = new float[width];

And then every draw cycle you can move all buffer locations down by one and add in a new value at location 0:

for (int i = width - 1; i > 0; i--) {
bufferValues[i] = bufferValues[i - 1];
}
bufferValues[0] = avgMinute;

Then to draw you can do something like:

background(0);
stroke(0, 255, 0);
strokeWeight(3);
noFill();
beginShape();
for (int i = 0; i < width; i++) {
vertex(i, height - bufferValues[i]);
}
endShape();

This is just off the top of my head, and I haven't actually tried it (mainly because I don't have the Timer class), but let me know how it works.

bob_holzer

Re: Seismograph

9 months ago

thank you so much baud.r, it works perfect! you made my day!

Top Reply

Response title

Attachments

New to this Portal?

Seismograph

Replies(4)

Re: Seismograph

Re: Seismograph

Re: Seismograph

Re: Seismograph

Statistics

Tags

Actions