second monitor window (and optimizing performance)

in Programming Questions • 2 years ago

Hi, I'm trying to make a copy of a applet window to use as a videomonitor, aside from the main applet that's being projected and not visible to me. I've succeeded to do this, but I have a feeling there's a better way of doing this (performance-wise).

I've found some info here and there on how to make a second appletwindow. But it's not really clear to me what's the most clever way to draw the same thing to both applets. Currently I'm drawing everything to the first one and copying the pixeldata to the second one like this:

secondApplet mApplet;
void draw() {
//drawing stuff here
loadPixels();
mApplet.loadPixels();
arrayCopy(pixels,mApplet.pixels);
mApplet.updatePixels();
mApplet.redraw();
}
//here's the applet stuff, in setup() I instantiate it with new PFrame();
public class PFrame extends Frame {
    public PFrame() {
        setBounds(10,10,640,480);
        mApplet = new secondApplet();
        add(mApplet);
        mApplet.init();
        //show();
        setVisible(true);
    }
}

public class secondApplet extends PApplet {
    public void setup() {
        size(640, 480);
        background(0);
        noLoop();
    }

    public void draw() {
    }
}

I'm noticing that it is a lot harder on the computer than when I'm drawing on only one applet, which makes perfect sense because I'm reading every pixel and writing it again, which seems redundant.

Would it be a good idea to draw to an off-screen PGraphics buffer first and then drawing that buffer on both applets with image()? Or is there a way to access the graphics buffer of the main applet and draw that into the second applet?

Any suggestions much appreciated.

Martijn

Replies(8)

motscousus

Re: second monitor window (and optimizing performance)

2 years ago

hi !

I have the exact same need/problem. i work in opengl so the best solution might be somewhat different for you.

one lead would be to use the off screen rendering or RenderToTexture (with opengl Frame Buffer Object) and then render the texture on both windows. But so far i had no real success. what i have been able to do is to render my sketch to a texture and then display it twice on screen within the same window. the performance was not that bad. however, i could not get it to display on a different window. my opengl talent stop there.

h

owaunandr..

Re: second monitor window (and optimizing performance)

2 years ago

You can check out this thread and see if it helps.

Switching renders on the fly

http://forum.processing.org/#topic/25080000000074131

kritzikra..

Re: second monitor window (and optimizing performance)

2 years ago

have you taken a look at the glgraphics library?
it definitely supports a second output window that is bound to the same gl context (which means you can draw the same fonts/images/etc without problems in it).

the url is http://glgraphics.sourceforge.net/

i haven't tested this, but it'd go a bit like this:

GLGraphicsOffscreen winGraphics; // the graphics object for the second window...
GLTextureWindow win;
void setup(){
size( 200, 200, GLConstants.GLGraphics );
win = new GLTextWindow( this, 100, 100, 400, 400 ); // 400x400 big at location 100,100
winGraphics = new GLGraphicsOffscreen( this, 400, 400 );
win.setTexture( winGraphics.getTexture() );
}
void draw(){
// do rendering of first screen just like you would normally
winGraphics.beginDraw();
// do all your drawing for the second window here
winGraphics.background ( 0 );
winGraphics.stroke( 255 );
winGraphics.line( 0, 0, 400, 400 );
winGraphics.endDraw();
}

maybe i forgot something, but you should get the idea...

good luck,
h,-

motscousus

Re: second monitor window (and optimizing performance)

2 years ago

i see ! thanks ! that looks exactly like what i am after.

trying this now and this looks quite good. and fast ! thanks for your help

martijn103

Re: second monitor window (and optimizing performance)

2 years ago

Thanks for the response!

I'm drawing into an GLGraphicsOffScreen now, and then showing it with image(GLGraphicsOffScreen.getTexture(),0,0) onto the main applet and then into a second GLTextureWindow which has the texture connected to it.

I haven't had the chance to really test the performance, but I looks great and fast so far...

pixelfren..

Re: second monitor window (and optimizing performance)

2 years ago

In case it's useful here's the GLGraphics code with some corrections to the spelling of methods and constants.

you also need to import the opengl library as well.

// 2-screen display based on code found at
// http://forum.processing.org/topic/second-monitor-window-and-optimizing-performance

import processing.opengl.*;
import codeanticode.glgraphics.*;


GLGraphicsOffScreen winGraphics; // the graphics object for the second window... 
GLTextureWindow win; 

void setup() {
  size( 200, 200, GLConstants.GLGRAPHICS ); 
  win = new GLTextureWindow( this, 100, 100, 400, 400 ); // 400x400 big at location 100,100
  winGraphics = new GLGraphicsOffScreen( this, 400, 400 ); 
  win.setTexture( winGraphics.getTexture() );
}

void draw() {
  // do rendering of first screen just like you would normally
  background(0);
  fill(64);
  ellipse(width/2, height/2, 50, 50);

  winGraphics.beginDraw(); 
  // do all your drawing for the second window here
  winGraphics.background ( 0 ); 
  winGraphics.stroke( 255 ); 
  winGraphics.line( 0, 0, 400, 400 ); 
  winGraphics.endDraw();
}