Yeah, PVectors can make the code a bit shorter sometimes and you can use some math stuff from them. In addition, suppose the circle is positioned at 0, 0 (origin), then the point (location) at the edge is also the outward normal. See the example, press any key to change the direction of the Particle.

Code Example

1. PVector origin = new PVector();
2. int diameter = 300;
3. int radius = diameter/2;
4. Particle p;
5.  
6. void setup() {
7.   size(500, 500);
8.   background(255);
9.   colorMode(HSB, 360, 100, 100);
10.   p = new Particle();
11.   noStroke();
12.   smooth();
13. }
14.  
15. void draw () {
16.   translate(width/2, height/2);
17.   fill(180, 0, 0, 5);
18.   ellipse(0, 0, diameter, diameter);
19.   p.update();
20.   p.display();
21. }
22.  
23. void keyPressed() { p.randomDirection(); }
24.  
25. class Particle {
26.   PVector loc, vel;
27.  
28.   Particle() {
29.     loc = new PVector(random(-width/2, width/2), random(-height/2, height/2));
30.     loc.limit(radius-50);
31.     randomDirection();
32.   }
33.  
34.   void update() {
35.     loc.add(vel);
36.     if (loc.dist(origin) > radius) {
37.       PVector n = loc.get();
38.       n.normalize();
39.       n.mult(2*n.dot(vel));
40.       vel.sub(n);
41.     }
42.   }
43.  
44.   void display() {
45.     fill(frameCount % 360, 100, 100);
46.     float eSize = 12 + sin(frameCount * 0.05) * 6;
47.     ellipse(loc.x, loc.y, eSize, eSize);
48.   }
49.  
50.   void randomDirection() {
51.     vel = new PVector(random(-1, 1), random(-1,1));
52.     vel.normalize();
53.     vel.mult(3);
54.   }
55. }