How to perform an action every x seconds? (time delays)

in Programming Questions • 1 year ago

Hey everyone, I'm new here and new to Processing so please forgive me if this is a really dumb question.

I am making a simple version of the game Missile Command. I've created a class called Missile which draws one "missile" (an ellipse) on the screen from one point on the screen to another.

What I want to do is create a loop that will call my moveMissile function every x amount of seconds. Preferably the amount of seconds could be a variable I can work with, e.g. to create different difficulty levels in the game.

I can use an if loop to check if a certain time has elapsed to draw only one missile with this:

int time = millis();
if (millis() > time + 2000)
{
miss.moveMissile();
}

which happens one time at the 2 second mark. Beyond that though I'm stumped!

Thanks in advance for any help!

Replies(10)

patakk

Re: How to perform an action every x seconds? (time delays)

1 year ago

int time = millis();
if (millis() > time + 2000)
{
miss.moveMissile();
time = millis();
}

Just add the "time = millis();" line because that way it starts to count from zero again, the difference between time and millis() is reseted.

amnon.owed

Re: How to perform an action every x seconds? (time delays)

1 year ago

You could also use frameCount and modulo, to trigger an event every x frames. However since you explicitly ask for every x seconds, indeed you could use millis(). The unfortunate thing about millis() is that it's not as strict as frameCount (1, 2, 3 etc.) so modulo won't work accurately with millis(). Therefore you have to construct the code so that it does get picked up. A good solution is to use a timer variable and check if >= (equal or more) time has passed since the last hit.

Code Example

int timer;
void setup() {
size(500, 500);
}
void draw() {
if (millis() - timer >= 2000) {
background(random(255));
timer = millis();
}
}

molleh

Re: How to perform an action every x seconds? (time delays)

1 year ago

Thanks very much both of you!

Now I have that code in and what it's doing is drawing the ellipse in my Missile class for one frame, waiting two seconds, drawing the next frame, etc.

To be more precise, I have created an array of 40 "missile"s and a loop that calls moveMissile(); for the length of the array. This gives me 40 missiles flying across the screen at once.

This is what I had originally, just to test that my array worked:

Missile[] missiles = new Missile[40];
PImage bgImage;
void setup()
{
size(640, 480);
smooth();
bgImage = loadImage("background.jpg");
for (int i = 0; i < missiles.length; i++)
{
missiles[i] = new Missile();
}
}
void draw()
{
image (bgImage, 0, 0);
for (int i = 0; i < missiles.length; i++)
{
missiles[i].moveMissile();
}
}

That draws 40 missiles moving across the screen at once. Adding time and millis() into the mix:

Missile[] missiles = new Missile[40];
int time;
PImage bgImage;
void setup()
{
size(640, 480);
smooth();
bgImage = loadImage("background.jpg");
for (int i = 0; i < missiles.length; i++)
{
missiles[i] = new Missile();
}
}
void draw()
{
image (bgImage, 0, 0);
for (int i = 0; i < missiles.length; i++)
{
if (millis() - time >= 2000)
{
missiles[i].moveMissile();
time = millis();
}
}
}

This is drawing one frame of moveMissile every 2 seconds instead of doing one complete moveMissile every 2 seconds.

Thanks very much for the help :)

amnon.owed

Re: How to perform an action every x seconds? (time delays)

1 year ago

I think I misunderstood you class structure, since you didn't post your Missile class.

I guess the time trigger should reset whatever is moving all those missiles.

Hard to tell without seeing the code.

Jonny Stu..

Re: How to perform an action every x seconds? (time delays)

1 year ago

You just need to nest the for loop inside the if statement instead of the other way round. Roughly:

if (time_condition) {
for (missiles) {
do_something;
}
time = millis();
}

molleh

Re: How to perform an action every x seconds? (time delays)

1 year ago

Thanks amnon and Jonny. I tried reversing the nesting of the loops like you said Jonny, but what that did was make all 40 missiles draw one frame every 2 seconds, instead of just 1 missile.

Here is the code from the Missile class, maybe this will help:

class Missile
{
//variables
float startX = 100 + random(440); // random start x-location at top of screen -100 pixels on each end
float stopX = 100 + random(440); // random end x-location at bottom of screen -100 pixels on each end
float startY = 0; // line will always start at 0 aka top of screen
float stopY = 380; // where line will stop
float x = startX; // sets up x coord
float y = startY; // sets up y coord
float step = 0.0015; // line speed
float pct = 0.0; // percent
//end variables
//constructor
Missile()
{
}//end constructor
//move missile
void moveMissile()
{
if (pct < 1.0) {
x = startX + ((stopX - startX) * pct);
y = startY + ((stopY - startY) * pct);
pct += step;
}//end if loop for missile x/y coords
fill(255,0,0);
ellipse(x, y, 5, 5);
}
}

Jonny Stu..

Re: How to perform an action every x seconds? (time delays)

1 year ago

Ah sorry, I somewhat misunderstood what you were after. So there should be one new missile every two seconds? The code gets closer to doing that. If you want the missile to complete in two seconds then you'll have to fiddle with the speeds. I commented out the image stuff for testing.

Missile[] missiles = new Missile[40];
int time;
int currentMissile;
PImage bgImage;
void setup()
{
size(640, 480);
smooth();
//bgImage = loadImage("background.jpg");
for (int i = 0; i < missiles.length; i++)
{
missiles[i] = new Missile();
}
currentMissile = 0;
}
void draw()
{
background(0);
missiles[currentMissile].moveMissile();
for (int i = 0; i < missiles.length; i++)
{
if (millis() - time >= 2000)
{
if (currentMissile < missiles.length - 1) {
currentMissile++;
}
time = millis();
}
}
}

molleh

Re: How to perform an action every x seconds? (time delays)

1 year ago

Hi Jonny,

Sorry for the late reply. Many thanks for your help so far! I put in your code, except I also switched over to frame-based timing because it keeps the code a lot simpler for now, and the basic idea is exactly the same.

What I have now is a missile[x] only draws for 50 frames, and then the next missile draws for 50 frames, then the next missile, etc. What I want to do is draw the missiles concurrently, so that each previous missile will keep on drawing until it "lands."

Here is the code so far, with the missile class inserted for ease of use:

Missile[] missiles = new Missile[40];
float time;
int currentMissile;
void setup()
{
size(640, 480);
smooth();
for (int i = 0; i < missiles.length; i++)
{
missiles[i] = new Missile();
}
time = 50;
currentMissile = 0;
}
class Missile
{
//variables
float startX = 100 + random(440); // random start x-location at top of screen -100 pixels on each end
float stopX = 100 + random(440); // random end x-location at bottom of screen -100 pixels on each end
float startY = 0; // line will always start at 0 aka top of screen
float stopY = 380; // where line will stop
float x = startX; // sets up x coord
float y = startY; // sets up y coord
float step = 0.0015; // line speed
float pct = 0.0; // percent
//end variables
//constructor
Missile()
{
}//end constructor
//move missile
void moveMissile()
{
if (pct < 1.0) {
x = startX + ((stopX - startX) * pct);
y = startY + ((stopY - startY) * pct);
pct += step;
}//end if loop for missile x/y coords
fill(255,0,0);
ellipse(x, y, 5, 5);
}
}
void draw()
{
time--;
background(255);
missiles[currentMissile].moveMissile();
for (int i = 0; i < missiles.length && time <= 0; i++)
{
if (currentMissile < missiles.length - 1)
{
currentMissile++;
}
time=50;
}
}

Thanks again in advance for any help!!

amnon.owed

Re: How to perform an action every x seconds? (time delays)

1 year ago

I think both for your program and conceptually it would make sense to have an arraylist of Missiles instead of an array. That way you can have however many missiles you want and let them all play out. Once they reach their destination, they can go through an explosion phase and then be removed from the arraylist. Here is an example of how to use an arraylist to update/remove and display the missiles.

Adapted Code

ArrayList <Missile> missiles = new ArrayList <Missile> ();
void setup() {
size(640, 480);
textAlign(CENTER, CENTER);
textSize(20);
smooth();
}
void draw() {
fill(255, 10);
rect(0, 0, width, height);
// add a missile every 50 frames
if (frameCount % 50 == 0) {
missiles.add(new Missile());
}
// update/remove and display all missiles
for (int i=missiles.size()-1; i>=0; i--) {
Missile m = missiles.get(i);
m.update();
m.display();
}
}
class Missile {
PVector start, stop, current;
float interpolation, interpolationSpeed;
Missile() {
start = new PVector(random(100, width-100), 0);
stop = new PVector(random(100, width-100), 380);
current = new PVector();
interpolationSpeed = random(0.005, 0.01);
}
void update() {
interpolation += interpolationSpeed;
if (interpolation > 1) {
text("BOOM!", current.x, current.y);
missiles.remove(this);
} else {
float ix = lerp(start.x, stop.x, interpolation);
float iy = lerp(start.y, stop.y, interpolation);
current.set(ix, iy, 0);
}
}
void display() {
noStroke();
fill(255, 0, 0);
ellipse(current.x, current.y, 5, 5);
}
}

molleh

Re: How to perform an action every x seconds? (time delays)

1 year ago

Thanks Amnon, very very helpful!

Top Reply

Response title

Attachments

New to this Portal?