Check out curvePoint().

Well my understanding of curvePoint is that you need to give a no. of points a,b,c,d to get the last one say e. What I want is to get the numbers between two points a and b. I guess it will have to be some sort of interpolation but I do no want linear interpolation so was wondering if processing provides such a mechanism or if there is some other implementation that I can find.

Check out curvePoint(). Again.

If you have a number of points (which you do) and you use curveVertex to make a shape (which you do) and you want to get the interpolated value between these points on the curve (which you want), then you can use curvePoint, right? Take a look at the following code example. Explain how curvePoint is not what you want...

Code Example

1. int currentCurvePoint;
2. PVector[] vecs = {
3.   new PVector(84, 91), // control point
4.   new PVector(84, 91),
5.   new PVector(68, 19),
6.   new PVector(21, 17),
7.   new PVector(32, 100),
8.   new PVector(32, 100) // control point
9. };
10.  
11. void setup() {
12.   size(200, 200);
13.   smooth();
14. }
15.  
16. void draw() {
17.   background(255);
18.   translate(50, 50);
19.   vecs[3].set(mouseX-50, mouseY-50, 0);
20.   drawShape();
21.   drawPoints();
22.   if (frameCount % 20 == 0) { currentCurvePoint++; }
23.   drawCurvePoint(currentCurvePoint % (vecs.length-3));
24. }
25.  
26. void drawShape() {
27.   noFill();
28.   stroke(0);
29.   beginShape();
30.   for (int i=0; i<vecs.length; i++) {
31.     curveVertex(vecs[i].x, vecs[i].y);
32.   }
33.   endShape();
34. }
35.  
36. void drawPoints() {
37.   noStroke();
38.   fill(255, 0, 0);
39.   for (int i=1; i<vecs.length-1; i++) {
40.     ellipse(vecs[i].x, vecs[i].y, 5, 5);
41.   }
42. }
43.  
44. void drawCurvePoint(int num) {
45.   noStroke();
46.   fill(0, 0, 255);
47.   float t = (frameCount % 20)/20.0;
48.   float x = curvePoint(vecs[num].x, vecs[num+1].x, vecs[num+2].x, vecs[num+3].x, t);
49.   float y = curvePoint(vecs[num].y, vecs[num+1].y, vecs[num+2].y, vecs[num+3].y, t);
50.   ellipse(x, y, 15, 15);
51. }

Well maybe I am so dumb that I am not getting the functionality of curvePoint() but what I understand is that it interpolates to the next value. So if I give 4 points in succession then its gonna give me the fifth point. I do not want that. In my code I only work on two points at a time so I wish to call a function that would calculate the values between these two points and draw a curve. Sorry if I am not grasping the concept. Can you look at my code and tell me how I will go about using curvePoint() since I don't have four points to begin with initially.

Thank you. I had the concept all wrong. This clears it up. I will get working on it right away. Thanks a lot for your help again :)