the easiest way would be to write them to a text file, check out the save file example

Showing your code might help...
But basically, I can guess you are trying to store a float in a String variable. In the pointed out example, the numbers are converted by concatenating them with a string. You can also use the str() function.

Hi,

The code looks as follows. I basically wish to store the size and rotation of squares in a text file, for each run of the program. Hope someone can help out:

void setup() {
  size(600, 600);
}
 
void draw() {
}
 
void mouseClicked() {
  background(255);
  rectMode(CENTER);
  int G = 100;
  float L = G / 2;
  ArrayList<PVector> gridPoints = new ArrayList<PVector>();
  for (int i=1; i<6; i++) {
    for (int j=1; j<6; j++) {
      ellipse(i*G, j*G, 5, 5);
      gridPoints.add(new PVector(i*100, j*100));
    }
  }
  for (int n=0;n<25;n++) {
    fill(255, 0, 0, 128);
    PVector point = gridPoints.remove(0);
    int theta = int(random(2*PI));
    float r = random(L);
    PVector one = new PVector(point.x + cos(theta) * r, point.y + sin(theta) * r);
    PVector two = new PVector(point.x + cos(theta + HALF_PI) * r, point.y + sin(theta + HALF_PI) * r);
    PVector three = new PVector(point.x + cos(theta + PI) * r, point.y + sin(theta + PI) * r);
    PVector four = new PVector(point.x + cos(theta - HALF_PI) * r, point.y + sin(theta - HALF_PI) * r);
 
    quad(one.x, one.y, two.x, two.y, three.x, three.y, four.x, four.y);
  }
}

I have attempted a simpler version, to get to the core, but I am still having problems

Why does the following not work (I am a beginner):

size(600, 600);
smooth();
background(0);
noStroke();
fill(226);

int xLength = int(random(25,50));
int yHeight = int(random(25,50));
int xPos = int(random(0 + xLength, width - xLength));
int yPos = int(random(0 + yHeight, width - yHeight));
rect(xPos, yPos, xLength, yHeight);

saveStrings("xPos.txt", xPos);

Because xPos is an integer, and it should be an array of strings to be used with saveStrings.
You should first convert it:

1. size(600, 600);
   smooth();
   background(0);
   noStroke();
   fill(226);
   
   int xLength = int(random(25,50));
   int yHeight = int(random(25,50));
   int xPos = int(random(0 + xLength, width - xLength));
   int yPos = int(random(0 + yHeight, width - yHeight));
   rect(xPos, yPos, xLength, yHeight);
   
   String[] xPos_ = { str(xPos) };
   
   saveStrings("xPos.txt", xPos_);
   

Thank you, much appreciated. So, I thought I could go on from here, trying to get more variables written in succession, but now I have hit another problem. Why does the following now work?

size(600, 600);
smooth();
background(0);
noStroke();
fill(226);

int xLength = int(random(25,50));
int yHeight = int(random(25,50));
int xPos = int(random(0 + xLength, width - xLength));
int yPos = int(random(0 + yHeight, width - yHeight));
rect(xPos, yPos, xLength, yHeight);

String[] xPos_ = { str(xPos) };
String[] yPos_ = { str(yPos) };
saveStrings("positions.txt", xPos_, yPos_ );

Because saveStrings function takes only 2 arguments. As xPos_ is an array, you can add the yPos integer too:

1. size(600, 600);
   smooth();
   background(0);
   noStroke();
   fill(226);
   
   int xLength = int(random(25,50));
   int yHeight = int(random(25,50));
   int xPos = int(random(0 + xLength, width - xLength));
   int yPos = int(random(0 + yHeight, width - yHeight));
   rect(xPos, yPos, xLength, yHeight);
   
   String[] coord = { str(xPos), str(yPos) };
   saveStrings("positions.txt", coord );

And if you want the coordinates on the same line:

1. String[] coord = { str(xPos) + " " + str(yPos) };
   saveStrings("positions.txt", coord );
   

This is really helping me, thank you! I think I got thist, and have added the size variables too...

I hope you can help me on this final question. What if I want to create a new image (and a new line on text in the file) every time I press a key, instead of having to run the program again and again?

My latest code is as follows:

size(600, 600);
smooth();
background(0);
noStroke();
fill(226);

int xLength = int(random(25,50));
int yHeight = int(random(25,50));
int xPos = int(random(0 + xLength, width - xLength));
int yPos = int(random(0 + yHeight, width - yHeight));
rect(xPos, yPos, xLength, yHeight);

String[] sizeAndCoord = { str(xLength) + " " + str(yHeight) + " " + str(xPos) + " " + str(yPos) };
saveStrings("output.txt", sizeAndCoord);

Do you really need to press a key to add a new line? With this code, you can specify how many loops you want, and write the coordinates all at once:

1. PrintWriter positions;
   int cycles = 100; //amount of rectangles
   
   
   void setup() {
     size(600, 600);
     smooth();
     background(0);
     noStroke();
     fill(226);
    
     positions = createWriter("positions.txt");
     noLoop();
   }
   
   void draw() {
     for (int i = 0; i < cycles; i++) {
       int xLength = int(random(25,50));
       int yHeight = int(random(25,50));
       int xPos = int(random(0 + xLength, width - xLength));
       int yPos = int(random(0 + yHeight, width - yHeight));
       rect(xPos, yPos, xLength, yHeight);
       positions.println(xLength + " " + yHeight + " " + xPos + " " + yPos);
     }
     positions.flush();
     positions.close();
   }
   
   

Well, firstly, your suggestion has given me more know-how, so thank you.

Perhaps some background information is useful. I am working towards creating an experiment, where users input information about what they see on the screen. They do this iteratively. So they see something, input data, go to the next screen, see something, input data, and so on. For that reason, having all the pictures drawn at once is not helpful (here). (I will eventually need to learn how to gather user data - but one thing at a time)

So, I would ideally like to be set on the right way for this. Which is why I asked about the key pressed event.

But thank you once again for your help.

Ok, I see. Maybe this is more suited to your needs. Each time Enter key is pressed, a line is added to the file. When "s" is pressed, it actually writes and closes the file.

1. PrintWriter positions;
   
   void setup() {
     size(600, 600);
     smooth();
     background(0);
     noStroke();
     fill(226);
     positions = createWriter("positions.txt");
   }
   
   void draw() {
   }
   
   void keyPressed() {
     if (keyCode == ENTER) {
       displayRectangle();
     }
     if (key == 's') {
       positions.flush();
       positions.close(); //write file
     }
   }
   
   void displayRectangle() {
     background(0); //clear screen
     int xLength = int(random(25,50));
     int yHeight = int(random(25,50));
     int xPos = int(random(0 + xLength, width - xLength));
     int yPos = int(random(0 + yHeight, width - yHeight));
     rect(xPos, yPos, xLength, yHeight);
     positions.println(xLength + " " + yHeight + " " + xPos + " " + yPos); //add line
   }
   
   
   

That is great! Thank you so much for your help.

You're welcome ;)